close Warning: Can't synchronize with repository "(default)" (The repository directory has changed, you should resynchronize the repository with: trac-admin $ENV repository resync '(default)'). Look in the Trac log for more information.

source: branches/f4grobner/polynomial.lisp@ 1915

Last change on this file since 1915 was 1915, checked in by Marek Rychlik, 9 years ago

* empty log message *
File size: 17.1 KB
Line 
1;;; -*- Mode: Lisp -*-
2;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
3;;;
4;;; Copyright (C) 1999, 2002, 2009, 2015 Marek Rychlik <rychlik@u.arizona.edu>
5;;;
6;;; This program is free software; you can redistribute it and/or modify
7;;; it under the terms of the GNU General Public License as published by
8;;; the Free Software Foundation; either version 2 of the License, or
9;;; (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
19;;;
20;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
21
22
23(defpackage "POLYNOMIAL"
24 (:use :cl :ring :ring-and-order :monom :order :term :termlist :infix)
25 (:export "POLY"
26 "POLY-TERMLIST"
27 "POLY-SUGAR"
28 "POLY-RESET-SUGAR"
29 "POLY-LT"
30 "MAKE-POLY-FROM-TERMLIST"
31 "MAKE-POLY-ZERO"
32 "MAKE-POLY-VARIABLE"
33 "POLY-UNIT"
34 "POLY-LM"
35 "POLY-SECOND-LM"
36 "POLY-SECOND-LT"
37 "POLY-LC"
38 "POLY-SECOND-LC"
39 "POLY-ZEROP"
40 "POLY-LENGTH"
41 "SCALAR-TIMES-POLY"
42 "SCALAR-TIMES-POLY-1"
43 "MONOM-TIMES-POLY"
44 "TERM-TIMES-POLY"
45 "POLY-ADD"
46 "POLY-SUB"
47 "POLY-UMINUS"
48 "POLY-MUL"
49 "POLY-EXPT"
50 "POLY-APPEND"
51 "POLY-NREVERSE"
52 "POLY-REVERSE"
53 "POLY-CONTRACT"
54 "POLY-EXTEND"
55 "POLY-ADD-VARIABLES"
56 "POLY-LIST-ADD-VARIABLES"
57 "POLY-STANDARD-EXTENSION"
58 "SATURATION-EXTENSION"
59 "POLYSATURATION-EXTENSION"
60 "SATURATION-EXTENSION-1"
61 "COERCE-COEFF"
62 "POLY-EVAL"
63 "POLY-EVAL-SCALAR"
64 "SPOLY"
65 "POLY-PRIMITIVE-PART"
66 "POLY-CONTENT"
67 "READ-INFIX-FORM"
68 "READ-POLY"
69 "STRING->POLY"
70 "POLY->ALIST"
71 "STRING->ALIST"
72 "POLY-EQUAL-NO-SUGAR-P"
73 "POLY-SET-EQUAL-NO-SUGAR-P"
74 "POLY-LIST-EQUAL-NO-SUGAR-P"
75 ))
76
77(in-package :polynomial)
78
79;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
80;;
81;; Polynomials
82;;
83;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
84
85(defstruct (poly
86 ;;
87 ;; BOA constructor, by default constructs zero polynomial
88 (:constructor make-poly-from-termlist (termlist &optional (sugar (termlist-sugar termlist))))
89 (:constructor make-poly-zero (&aux (termlist nil) (sugar -1)))
90 ;; Constructor of polynomials representing a variable
91 (:constructor make-poly-variable (ring nvars pos &optional (power 1)
92 &aux
93 (termlist (list
94 (make-term-variable ring nvars pos power)))
95 (sugar power)))
96 (:constructor poly-unit (ring dimension
97 &aux
98 (termlist (termlist-unit ring dimension))
99 (sugar 0))))
100 (termlist nil :type list)
101 (sugar -1 :type fixnum))
102
103;; Leading term
104(defmacro poly-lt (p) `(car (poly-termlist ,p)))
105
106;; Second term
107(defmacro poly-second-lt (p) `(cadar (poly-termlist ,p)))
108
109;; Leading monomial
110(defun poly-lm (p)
111 (declare (type poly p))
112 (term-monom (poly-lt p)))
113
114;; Second monomial
115(defun poly-second-lm (p)
116 (declare (type poly p))
117 (term-monom (poly-second-lt p)))
118
119;; Leading coefficient
120(defun poly-lc (p)
121 (declare (type poly p))
122 (term-coeff (poly-lt p)))
123
124;; Second coefficient
125(defun poly-second-lc (p)
126 (declare (type poly p))
127 (term-coeff (poly-second-lt p)))
128
129;; Testing for a zero polynomial
130(defun poly-zerop (p)
131 (declare (type poly p))
132 (null (poly-termlist p)))
133
134;; The number of terms
135(defun poly-length (p)
136 (declare (type poly p))
137 (length (poly-termlist p)))
138
139(defun poly-reset-sugar (p)
140 "(Re)sets the sugar of a polynomial P to the sugar of (POLY-TERMLIST P).
141Thus, the sugar is set to the maximum sugar of all monomials of P, or -1
142if P is a zero polynomial."
143 (declare (type poly p))
144 (setf (poly-sugar p) (termlist-sugar (poly-termlist p)))
145 p)
146
147(defun scalar-times-poly (ring c p)
148 "The scalar product of scalar C by a polynomial P. The sugar of the
149original polynomial becomes the sugar of the result."
150 (declare (type ring ring) (type poly p))
151 (make-poly-from-termlist (scalar-times-termlist ring c (poly-termlist p)) (poly-sugar p)))
152
153(defun scalar-times-poly-1 (ring c p)
154 "The scalar product of scalar C by a polynomial P, omitting the head term. The sugar of the
155original polynomial becomes the sugar of the result."
156 (declare (type ring ring) (type poly p))
157 (make-poly-from-termlist (scalar-times-termlist ring c (cdr (poly-termlist p))) (poly-sugar p)))
158
159(defun monom-times-poly (m p)
160 (declare (type monom m) (type poly p))
161 (make-poly-from-termlist
162 (monom-times-termlist m (poly-termlist p))
163 (+ (poly-sugar p) (monom-sugar m))))
164
165(defun term-times-poly (ring term p)
166 (declare (type ring ring) (type term term) (type poly p))
167 (make-poly-from-termlist
168 (term-times-termlist ring term (poly-termlist p))
169 (+ (poly-sugar p) (term-sugar term))))
170
171(defun poly-add (ring-and-order p q)
172 (declare (type ring-and-order ring-and-order) (type poly p q))
173 (make-poly-from-termlist
174 (termlist-add ring-and-order
175 (poly-termlist p)
176 (poly-termlist q))
177 (max (poly-sugar p) (poly-sugar q))))
178
179(defun poly-sub (ring-and-order p q)
180 (declare (type ring-and-order ring-and-order) (type poly p q))
181 (make-poly-from-termlist
182 (termlist-sub ring-and-order (poly-termlist p) (poly-termlist q))
183 (max (poly-sugar p) (poly-sugar q))))
184
185(defun poly-uminus (ring p)
186 (declare (type ring ring) (type poly p))
187 (make-poly-from-termlist
188 (termlist-uminus ring (poly-termlist p))
189 (poly-sugar p)))
190
191(defun poly-mul (ring-and-order p q)
192 (declare (type ring-and-order ring-and-order) (type poly p q))
193 (make-poly-from-termlist
194 (termlist-mul ring-and-order (poly-termlist p) (poly-termlist q))
195 (+ (poly-sugar p) (poly-sugar q))))
196
197(defun poly-expt (ring-and-order p n)
198 (declare (type ring-and-order ring-and-order) (type poly p))
199 (make-poly-from-termlist (termlist-expt ring-and-order (poly-termlist p) n) (* n (poly-sugar p))))
200
201(defun poly-append (&rest plist)
202 (make-poly-from-termlist (apply #'append (mapcar #'poly-termlist plist))
203 (apply #'max (mapcar #'poly-sugar plist))))
204
205(defun poly-nreverse (p)
206 "Destructively reverse the order of terms in polynomial P. Returns P"
207 (declare (type poly p))
208 (setf (poly-termlist p) (nreverse (poly-termlist p)))
209 p)
210
211(defun poly-reverse (p)
212 "Returns a copy of the polynomial P with terms in reverse order."
213 (declare (type poly p))
214 (make-poly-from-termlist (reverse (poly-termlist p))
215 (poly-sugar p)))
216
217
218(defun poly-contract (p &optional (k 1))
219 (declare (type poly p))
220 (make-poly-from-termlist (termlist-contract (poly-termlist p) k)
221 (poly-sugar p)))
222
223(defun poly-extend (p &optional (m (make-monom :dimension 1)))
224 (declare (type poly p))
225 (make-poly-from-termlist
226 (termlist-extend (poly-termlist p) m)
227 (+ (poly-sugar p) (monom-sugar m))))
228
229(defun poly-add-variables (p k)
230 (declare (type poly p))
231 (setf (poly-termlist p) (termlist-add-variables (poly-termlist p) k))
232 p)
233
234(defun poly-list-add-variables (plist k)
235 (mapcar #'(lambda (p) (poly-add-variables p k)) plist))
236
237(defun poly-standard-extension (plist &aux (k (length plist)))
238 "Calculate [U1*P1,U2*P2,...,UK*PK], where PLIST=[P1,P2,...,PK]."
239 (declare (list plist) (fixnum k))
240 (labels ((incf-power (g i)
241 (dolist (x (poly-termlist g))
242 (incf (monom-elt (term-monom x) i)))
243 (incf (poly-sugar g))))
244 (setf plist (poly-list-add-variables plist k))
245 (dotimes (i k plist)
246 (incf-power (nth i plist) i))))
247
248(defun saturation-extension (ring f plist
249 &aux
250 (k (length plist))
251 (d (monom-dimension (poly-lm (car plist))))
252 f-x plist-x)
253 "Calculate [F, U1*P1-1,U2*P2-1,...,UK*PK-1], where PLIST=[P1,P2,...,PK]."
254 (declare (type ring ring))
255 (setf f-x (poly-list-add-variables f k)
256 plist-x (mapcar #'(lambda (x)
257 (setf (poly-termlist x)
258 (nconc (poly-termlist x)
259 (list (make-term :monom (make-monom :dimension d)
260 :coeff (funcall (ring-uminus ring)
261 (funcall (ring-unit ring)))))))
262 x)
263 (poly-standard-extension plist)))
264 (append f-x plist-x))
265
266
267(defun polysaturation-extension (ring f plist
268 &aux
269 (k (length plist))
270 (d (+ k (monom-dimension (poly-lm (car plist)))))
271 ;; Add k variables to f
272 (f (poly-list-add-variables f k))
273 ;; Set PLIST to [U1*P1,U2*P2,...,UK*PK]
274 (plist (apply #'poly-append (poly-standard-extension plist))))
275 "Calculate [F, U1*P1+U2*P2+...+UK*PK-1], where PLIST=[P1,P2,...,PK]. It destructively modifies F."
276 ;; Add -1 as the last term
277 (declare (type ring ring))
278 (setf (cdr (last (poly-termlist plist)))
279 (list (make-term :monom (make-monom :dimension d)
280 :coeff (funcall (ring-uminus ring) (funcall (ring-unit ring))))))
281 (append f (list plist)))
282
283(defun saturation-extension-1 (ring f p)
284 "Calculate [F, U*P-1]. It destructively modifies F."
285 (declare (type ring ring))
286 (polysaturation-extension ring f (list p)))
287
288;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
289;;
290;; Evaluation of polynomial (prefix) expressions
291;;
292;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
293
294(defun coerce-coeff (ring expr vars)
295 "Coerce an element of the coefficient ring to a constant polynomial."
296 ;; Modular arithmetic handler by rat
297 (declare (type ring ring))
298 (make-poly-from-termlist (list (make-term :monom (make-monom :dimension (length vars))
299 :coeff (funcall (ring-parse ring) expr)))
300 0))
301
302(defun poly-eval (expr vars
303 &optional
304 (ring +ring-of-integers+)
305 (order #'lex>)
306 (list-marker :[)
307 &aux
308 (ring-and-order (make-ring-and-order :ring ring :order order)))
309 "Evaluate Lisp form EXPR to a polynomial or a list of polynomials in
310variables VARS. Return the resulting polynomial or list of
311polynomials. Standard arithmetical operators in form EXPR are
312replaced with their analogues in the ring of polynomials, and the
313resulting expression is evaluated, resulting in a polynomial or a list
314of polynomials in internal form. A similar operation in another computer
315algebra system could be called 'expand' or so."
316 (declare (type ring ring))
317 (labels ((p-eval (arg) (poly-eval arg vars ring order))
318 (p-eval-scalar (arg) (poly-eval-scalar arg))
319 (p-eval-list (args) (mapcar #'p-eval args))
320 (p-add (x y) (poly-add ring-and-order x y)))
321 (cond
322 ((null expr) (error "Empty expression"))
323 ((eql expr 0) (make-poly-zero))
324 ((member expr vars :test #'equalp)
325 (let ((pos (position expr vars :test #'equalp)))
326 (make-poly-variable ring (length vars) pos)))
327 ((atom expr)
328 (coerce-coeff ring expr vars))
329 ((eq (car expr) list-marker)
330 (cons list-marker (p-eval-list (cdr expr))))
331 (t
332 (case (car expr)
333 (+ (reduce #'p-add (p-eval-list (cdr expr))))
334 (- (case (length expr)
335 (1 (make-poly-zero))
336 (2 (poly-uminus ring (p-eval (cadr expr))))
337 (3 (poly-sub ring-and-order (p-eval (cadr expr)) (p-eval (caddr expr))))
338 (otherwise (poly-sub ring-and-order (p-eval (cadr expr))
339 (reduce #'p-add (p-eval-list (cddr expr)))))))
340 (*
341 (if (endp (cddr expr)) ;unary
342 (p-eval (cdr expr))
343 (reduce #'(lambda (p q) (poly-mul ring-and-order p q)) (p-eval-list (cdr expr)))))
344 (/
345 ;; A polynomial can be divided by a scalar
346 (cond
347 ((endp (cddr expr))
348 ;; A special case (/ ?), the inverse
349 (coerce-coeff ring (apply (ring-div ring) (cdr expr)) vars))
350 (t
351 (let ((num (p-eval (cadr expr)))
352 (denom-inverse (apply (ring-div ring)
353 (cons (funcall (ring-unit ring))
354 (mapcar #'p-eval-scalar (cddr expr))))))
355 (scalar-times-poly ring denom-inverse num)))))
356 (expt
357 (cond
358 ((member (cadr expr) vars :test #'equalp)
359 ;;Special handling of (expt var pow)
360 (let ((pos (position (cadr expr) vars :test #'equalp)))
361 (make-poly-variable ring (length vars) pos (caddr expr))))
362 ((not (and (integerp (caddr expr)) (plusp (caddr expr))))
363 ;; Negative power means division in coefficient ring
364 ;; Non-integer power means non-polynomial coefficient
365 (coerce-coeff ring expr vars))
366 (t (poly-expt ring-and-order (p-eval (cadr expr)) (caddr expr)))))
367 (otherwise
368 (coerce-coeff ring expr vars)))))))
369
370(defun poly-eval-scalar (expr
371 &optional
372 (ring +ring-of-integers+)
373 &aux
374 (order #'lex>))
375 "Evaluate a scalar expression EXPR in ring RING."
376 (declare (type ring ring))
377 (poly-lc (poly-eval expr nil ring order)))
378
379(defun spoly (ring-and-order f g
380 &aux
381 (ring (ro-ring ring-and-order)))
382 "It yields the S-polynomial of polynomials F and G."
383 (declare (type ring-and-order ring-and-order) (type poly f g))
384 (let* ((lcm (monom-lcm (poly-lm f) (poly-lm g)))
385 (mf (monom-div lcm (poly-lm f)))
386 (mg (monom-div lcm (poly-lm g))))
387 (declare (type monom mf mg))
388 (multiple-value-bind (c cf cg)
389 (funcall (ring-ezgcd ring) (poly-lc f) (poly-lc g))
390 (declare (ignore c))
391 (poly-sub
392 ring-and-order
393 (scalar-times-poly ring cg (monom-times-poly mf f))
394 (scalar-times-poly ring cf (monom-times-poly mg g))))))
395
396
397(defun poly-primitive-part (ring p)
398 "Divide polynomial P with integer coefficients by gcd of its
399coefficients and return the result."
400 (declare (type ring ring) (type poly p))
401 (if (poly-zerop p)
402 (values p 1)
403 (let ((c (poly-content ring p)))
404 (values (make-poly-from-termlist
405 (mapcar
406 #'(lambda (x)
407 (make-term :monom (term-monom x)
408 :coeff (funcall (ring-div ring) (term-coeff x) c)))
409 (poly-termlist p))
410 (poly-sugar p))
411 c))))
412
413(defun poly-content (ring p)
414 "Greatest common divisor of the coefficients of the polynomial P. Use the RING structure
415to compute the greatest common divisor."
416 (declare (type ring ring) (type poly p))
417 (reduce (ring-gcd ring) (mapcar #'term-coeff (rest (poly-termlist p))) :initial-value (poly-lc p)))
418
419(defun read-infix-form (&key (stream t))
420 "Parser of infix expressions with integer/rational coefficients
421The parser will recognize two kinds of polynomial expressions:
422
423- polynomials in fully expanded forms with coefficients
424 written in front of symbolic expressions; constants can be optionally
425 enclosed in (); for example, the infix form
426 X^2-Y^2+(-4/3)*U^2*W^3-5
427 parses to
428 (+ (- (EXPT X 2) (EXPT Y 2)) (* (- (/ 4 3)) (EXPT U 2) (EXPT W 3)) (- 5))
429
430- lists of polynomials; for example
431 [X-Y, X^2+3*Z]
432 parses to
433 (:[ (- X Y) (+ (EXPT X 2) (* 3 Z)))
434 where the first symbol [ marks a list of polynomials.
435
436-other infix expressions, for example
437 [(X-Y)*(X+Y)/Z,(X+1)^2]
438parses to:
439 (:[ (/ (* (- X Y) (+ X Y)) Z) (EXPT (+ X 1) 2))
440Currently this function is implemented using M. Kantrowitz's INFIX package."
441 (read-from-string
442 (concatenate 'string
443 "#I("
444 (with-output-to-string (s)
445 (loop
446 (multiple-value-bind (line eof)
447 (read-line stream t)
448 (format s "~A" line)
449 (when eof (return)))))
450 ")")))
451
452(defun read-poly (vars &key
453 (stream t)
454 (ring +ring-of-integers+)
455 (order #'lex>))
456 "Reads an expression in prefix form from a stream STREAM.
457The expression read from the strem should represent a polynomial or a
458list of polynomials in variables VARS, over the ring RING. The
459polynomial or list of polynomials is returned, with terms in each
460polynomial ordered according to monomial order ORDER."
461 (poly-eval (read-infix-form :stream stream) vars ring order))
462
463(defun string->poly (str vars
464 &optional
465 (ring +ring-of-integers+)
466 (order #'lex>))
467 "Converts a string STR to a polynomial in variables VARS."
468 (with-input-from-string (s str)
469 (read-poly vars :stream s :ring ring :order order)))
470
471(defun poly->alist (p)
472 "Convert a polynomial P to an association list. Thus, the format of the
473returned value is ((MONOM[0] . COEFF[0]) (MONOM[1] . COEFF[1]) ...), where
474MONOM[I] is a list of exponents in the monomial and COEFF[I] is the
475corresponding coefficient in the ring."
476 (cond
477 ((poly-p p)
478 (mapcar #'term->cons (poly-termlist p)))
479 ((and (consp p) (eq (car p) :[))
480 (cons :[ (mapcar #'poly->alist (cdr p))))))
481
482(defun string->alist (str vars
483 &optional
484 (ring +ring-of-integers+)
485 (order #'lex>))
486 "Convert a string STR representing a polynomial or polynomial list to
487an association list (... (MONOM . COEFF) ...)."
488 (poly->alist (string->poly str vars ring order)))
489
490(defun poly-equal-no-sugar-p (p q)
491 "Compare polynomials for equality, ignoring sugar."
492 (declare (type poly p q))
493 (equalp (poly-termlist p) (poly-termlist q)))
494
495(defun poly-set-equal-no-sugar-p (p q)
496 "Compare polynomial sets P and Q for equality, ignoring sugar."
497 (null (set-exclusive-or p q :test #'poly-equal-no-sugar-p )))
498
499(defun poly-list-equal-no-sugar-p (p q)
500 "Compare polynomial lists P and Q for equality, ignoring sugar."
501 (declare (type poly p q))
502 (every #'poly-equal-no-sugar-p p q))
Note: See TracBrowser for help on using the repository browser.