close Warning: Can't synchronize with repository "(default)" (The repository directory has changed, you should resynchronize the repository with: trac-admin $ENV repository resync '(default)'). Look in the Trac log for more information.

source: branches/f4grobner/polynomial.lisp@ 3505

Last change on this file since 3505 was 3505, checked in by Marek Rychlik, 9 years ago

* empty log message *
File size: 17.1 KB
Line 
1;;----------------------------------------------------------------
2;; File: polynomial.lisp
3;;----------------------------------------------------------------
4;;
5;; Author: Marek Rychlik (rychlik@u.arizona.edu)
6;; Date: Thu Aug 27 09:41:24 2015
7;; Copying: (C) Marek Rychlik, 2010. All rights reserved.
8;;
9;;----------------------------------------------------------------
10;;; -*- Mode: Lisp -*-
11;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
12;;;
13;;; Copyright (C) 1999, 2002, 2009, 2015 Marek Rychlik <rychlik@u.arizona.edu>
14;;;
15;;; This program is free software; you can redistribute it and/or modify
16;;; it under the terms of the GNU General Public License as published by
17;;; the Free Software Foundation; either version 2 of the License, or
18;;; (at your option) any later version.
19;;;
20;;; This program is distributed in the hope that it will be useful,
21;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
22;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
23;;; GNU General Public License for more details.
24;;;
25;;; You should have received a copy of the GNU General Public License
26;;; along with this program; if not, write to the Free Software
27;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
28;;;
29;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
30
31(defpackage "POLYNOMIAL"
32 (:use :cl :utils :monom)
33 (:export "POLY"
34 "POLY-DIMENSION"
35 "POLY-TERMLIST"
36 "POLY-TERM-ORDER"
37 "CHANGE-TERM-ORDER"
38 "STANDARD-EXTENSION"
39 "STANDARD-EXTENSION-1"
40 "STANDARD-SUM"
41 "SATURATION-EXTENSION"
42 "ALIST->POLY")
43 (:documentation "Implements polynomials. A polynomial is essentially
44a mapping of monomials of the same degree to coefficients. The
45momomials are ordered according to a monomial order."))
46
47(in-package :polynomial)
48
49(proclaim '(optimize (speed 3) (space 0) (safety 0) (debug 0)))
50
51(defclass poly ()
52 ((dimension :initform nil
53 :initarg :dimension
54 :accessor poly-dimension
55 :documentation "Shared dimension of all terms, the number of variables")
56 (termlist :initform nil :initarg :termlist :accessor poly-termlist
57 :documentation "List of terms.")
58 (order :initform #'lex> :initarg :order :accessor poly-term-order
59 :documentation "Monomial/term order."))
60 (:default-initargs :dimension nil :termlist nil :order #'lex>)
61 (:documentation "A polynomial with a list of terms TERMLIST, ordered
62according to term order ORDER, which defaults to LEX>."))
63
64(defmethod print-object ((self poly) stream)
65 (print-unreadable-object (self stream :type t :identity t)
66 (with-accessors ((dimension poly-dimension)
67 (termlist poly-termlist)
68 (order poly-term-order))
69 self
70 (format stream "DIMENSION=~A TERMLIST=~A ORDER=~A"
71 dimension termlist order))))
72
73(defgeneric change-term-order (self other)
74 (:documentation "Change term order of SELF to the term order of OTHER.")
75 (:method ((self poly) (other poly))
76 (unless (eq (poly-term-order self) (poly-term-order other))
77 (setf (poly-termlist self) (sort (poly-termlist self) (poly-term-order other))
78 (poly-term-order self) (poly-term-order other)))
79 self))
80
81(defun alist->poly (alist &aux (poly (make-instance 'poly)))
82 "It reads polynomial from an alist formatted as ( ... (exponents . coeff) ...).
83It can be used to enter simple polynomials by hand, e.g the polynomial
84in two variables, X and Y, given in standard notation as:
85
86 3*X^2*Y^3+2*Y+7
87
88can be entered as
89(ALIST->POLY '(((2 3) . 3) ((0 1) . 2) ((0 0) . 7))).
90
91NOTE: The primary use is for low-level debugging of the package."
92 (dolist (x alist poly)
93 (poly-insert-term poly (make-instance 'monom :exponents (car x)) (cdr x))))
94
95(defmethod update-instance-for-different-class :after ((old monom) (new poly) &key)
96 "Converts OLD of class MONOM to a NEW of class POLY, by making it into a 1-element TERMLIST."
97 (reinitialize-instance new
98 :dimension (monom-dimension old)
99 :termlist (list (cons monom 1))))
100
101(defmethod r-equalp ((self poly) (other poly))
102 "POLY instances are R-EQUALP if they have the same
103order and if all terms are R-EQUALP."
104 (and (every #'r-equalp (poly-termlist self) (poly-termlist other))
105 (eq (poly-term-order self) (poly-term-order other))))
106
107(defgeneric poly-insert-term (self monom coeff)
108 (:method ((self poly) (monom monom) coeff)
109 (cond ((null (poly-dimension self))
110 (setf (poly-dimension self) (monom-dimension monom)))
111 (t (assert (= (poly-dimension self) (monom-dimension monom)))))
112 (push (cons monom coeff) (poly-termlist self))
113 self))
114
115(defgeneric poly-append-term (self monom coeff)
116 (:method ((self poly) (monom monom) coeff)
117 (cond ((null (poly-dimension self))
118 (setf (poly-dimension self) (monom-dimension monom)))
119 (t (assert (= (poly-dimension self) (monom-dimension monom)))))
120 (setf (cdr (last (poly-termlist self))) (list (cons monom coeff)))
121 self))
122
123;; Leading term
124(defgeneric leading-term (object)
125 (:method ((self poly))
126 (car (poly-termlist self)))
127 (:documentation "The leading term of a polynomial, or NIL for zero polynomial."))
128
129;; Second term
130(defgeneric second-leading-term (object)
131 (:method ((self poly))
132 (cadar (poly-termlist self)))
133 (:documentation "The second leading term of a polynomial, or NIL for a polynomial with at most one term."))
134
135;; Leading coefficient
136(defgeneric leading-coefficient (object)
137 (:method ((self poly))
138 (scalar-coeff (leading-term self)))
139 (:documentation "The leading coefficient of a polynomial. It signals error for a zero polynomial."))
140
141;; Second coefficient
142(defgeneric second-leading-coefficient (object)
143 (:method ((self poly))
144 (scalar-coeff (second-leading-term self)))
145 (:documentation "The second leading coefficient of a polynomial. It
146 signals error for a polynomial with at most one term."))
147
148;; Testing for a zero polynomial
149(defmethod r-zerop ((self poly))
150 (null (poly-termlist self)))
151
152;; The number of terms
153(defmethod r-length ((self poly))
154 (length (poly-termlist self)))
155
156(defmethod multiply-by ((self poly) (other monom))
157 (mapc #'(lambda (term) (multiply-by term other))
158 (poly-termlist self))
159 self)
160
161(defmethod multiply-by ((self poly) (other term))
162 (mapc #'(lambda (term) (multiply-by term other))
163 (poly-termlist self))
164 self)
165
166(defmethod multiply-by ((self poly) (other scalar))
167 (mapc #'(lambda (term) (multiply-by term other))
168 (poly-termlist self))
169 self)
170
171
172(defmacro fast-add/subtract (p q order-fn add/subtract-fn uminus-fn)
173 "Return an expression which will efficiently adds/subtracts two
174polynomials, P and Q. The addition/subtraction of coefficients is
175performed by calling ADD/SUBTRACT-METHOD-NAME. If UMINUS-METHOD-NAME
176is supplied, it is used to negate the coefficients of Q which do not
177have a corresponding coefficient in P. The code implements an
178efficient algorithm to add two polynomials represented as sorted lists
179of terms. The code destroys both arguments, reusing the terms to build
180the result."
181 `(macrolet ((lc (x) `(scalar-coeff (car ,x))))
182 (do ((p ,p)
183 (q ,q)
184 r)
185 ((or (endp p) (endp q))
186 ;; NOTE: R contains the result in reverse order. Can it
187 ;; be more efficient to produce the terms in correct order?
188 (unless (endp q)
189 ;; Upon subtraction, we must change the sign of
190 ;; all coefficients in q
191 ,@(when uminus-fn
192 `((mapc #'(lambda (x) (setf x (funcall ,uminus-fn x))) q)))
193 (setf r (nreconc r q)))
194 r)
195 (multiple-value-bind
196 (greater-p equal-p)
197 (funcall ,order-fn (car p) (car q))
198 (cond
199 (greater-p
200 (rotatef (cdr p) r p)
201 )
202 (equal-p
203 (let ((s (funcall ,add/subtract-fn (lc p) (lc q))))
204 (cond
205 ((r-zerop s)
206 (setf p (cdr p))
207 )
208 (t
209 (setf (lc p) s)
210 (rotatef (cdr p) r p))))
211 (setf q (cdr q))
212 )
213 (t
214 ;;Negate the term of Q if UMINUS provided, signallig
215 ;;that we are doing subtraction
216 ,(when uminus-fn
217 `(setf (lc q) (funcall ,uminus-fn (lc q))))
218 (rotatef (cdr q) r q)))))))
219
220
221(defmacro def-add/subtract-method (add/subtract-method-name
222 uminus-method-name
223 &optional
224 (doc-string nil doc-string-supplied-p))
225 "This macro avoids code duplication for two similar operations: ADD-TO and SUBTRACT-FROM."
226 `(defmethod ,add/subtract-method-name ((self poly) (other poly))
227 ,@(when doc-string-supplied-p `(,doc-string))
228 ;; Ensure orders are compatible
229 (change-term-order other self)
230 (setf (poly-termlist self) (fast-add/subtract
231 (poly-termlist self) (poly-termlist other)
232 (poly-term-order self)
233 #',add/subtract-method-name
234 ,(when uminus-method-name `(function ,uminus-method-name))))
235 self))
236
237(eval-when (:compile-toplevel :load-toplevel :execute)
238
239 (def-add/subtract-method add-to nil
240 "Adds to polynomial SELF another polynomial OTHER.
241This operation destructively modifies both polynomials.
242The result is stored in SELF. This implementation does
243no consing, entirely reusing the sells of SELF and OTHER.")
244
245 (def-add/subtract-method subtract-from unary-minus
246 "Subtracts from polynomial SELF another polynomial OTHER.
247This operation destructively modifies both polynomials.
248The result is stored in SELF. This implementation does
249no consing, entirely reusing the sells of SELF and OTHER.")
250 )
251
252(defmethod unary-minus ((self poly))
253 "Destructively modifies the coefficients of the polynomial SELF,
254by changing their sign."
255 (mapc #'unary-minus (poly-termlist self))
256 self)
257
258(defun add-termlists (p q order-fn)
259 "Destructively adds two termlists P and Q ordered according to ORDER-FN."
260 (fast-add/subtract p q order-fn #'add-to nil))
261
262(defmacro multiply-term-by-termlist-dropping-zeros (term termlist
263 &optional (reverse-arg-order-P nil))
264 "Multiplies term TERM by a list of term, TERMLIST.
265Takes into accound divisors of zero in the ring, by
266deleting zero terms. Optionally, if REVERSE-ARG-ORDER-P
267is T, change the order of arguments; this may be important
268if we extend the package to non-commutative rings."
269 `(mapcan #'(lambda (other-term)
270 (let ((prod (r*
271 ,@(cond
272 (reverse-arg-order-p
273 `(other-term ,term))
274 (t
275 `(,term other-term))))))
276 (cond
277 ((r-zerop prod) nil)
278 (t (list prod)))))
279 ,termlist))
280
281(defun multiply-termlists (p q order-fn)
282 "A version of polynomial multiplication, operating
283directly on termlists."
284 (cond
285 ((or (endp p) (endp q))
286 ;;p or q is 0 (represented by NIL)
287 nil)
288 ;; If p= p0+p1 and q=q0+q1 then p*q=p0*q0+p0*q1+p1*q
289 ((endp (cdr p))
290 (multiply-term-by-termlist-dropping-zeros (car p) q))
291 ((endp (cdr q))
292 (multiply-term-by-termlist-dropping-zeros (car q) p t))
293 (t
294 (cons (r* (car p) (car q))
295 (add-termlists
296 (multiply-term-by-termlist-dropping-zeros (car p) (cdr q))
297 (multiply-termlists (cdr p) q order-fn)
298 order-fn)))))
299
300(defmethod multiply-by ((self poly) (other poly))
301 (change-term-order other self)
302 (setf (poly-termlist self) (multiply-termlists (poly-termlist self)
303 (poly-termlist other)
304 (poly-term-order self)))
305 self)
306
307(defmethod r+ ((poly1 poly) poly2)
308 "Non-destructively add POLY1 by POLY2."
309 (add-to (copy-instance POLY1) (change-class (copy-instance POLY2) 'poly)))
310
311(defmethod r- ((minuend poly) &rest subtrahends)
312 "Non-destructively subtract MINUEND and SUBTRAHENDS."
313 (subtract-from (copy-instance minuend)
314 (change-class (reduce #'r+ subtrahends) 'poly)))
315
316(defmethod r+ ((poly1 term) poly2)
317 "Non-destructively add POLY1 by POLY2."
318 (add-to (change-class (copy-instance poly1) 'poly)
319 (change-class (copy-instance poly2) 'poly)))
320
321(defmethod r- ((minuend term) &rest subtrahends)
322 "Non-destructively subtract MINUEND and SUBTRAHENDS."
323 (subtract-from (change-class (copy-instance minuend) 'poly)
324 (change-class (reduce #'r+ subtrahends) 'poly)))
325
326(defmethod r+ ((poly1 monom) poly2)
327 "Non-destructively add POLY1 by POLY2."
328 (add-to (change-class (copy-instance poly1) 'poly)
329 (change-class (copy-instance poly2) 'poly)))
330
331(defmethod r- ((minuend monom) &rest subtrahends)
332 "Non-destructively subtract MINUEND and SUBTRAHENDS."
333 (subtract-from (change-class (copy-instance minuend) 'poly)
334 (change-class (reduce #'r+ subtrahends) 'poly)))
335
336(defmethod r* ((poly1 poly) (poly2 poly))
337 "Non-destructively multiply POLY1 by POLY2."
338 (multiply-by (copy-instance poly1) (copy-instance poly2)))
339
340(defmethod left-tensor-product-by ((self poly) (other term))
341 (setf (poly-termlist self)
342 (mapcan #'(lambda (term)
343 (let ((prod (left-tensor-product-by term other)))
344 (cond
345 ((r-zerop prod) nil)
346 (t (list prod)))))
347 (poly-termlist self)))
348 self)
349
350(defmethod right-tensor-product-by ((self poly) (other term))
351 (setf (poly-termlist self)
352 (mapcan #'(lambda (term)
353 (let ((prod (right-tensor-product-by term other)))
354 (cond
355 ((r-zerop prod) nil)
356 (t (list prod)))))
357 (poly-termlist self)))
358 self)
359
360(defmethod left-tensor-product-by ((self poly) (other monom))
361 (setf (poly-termlist self)
362 (mapcan #'(lambda (term)
363 (let ((prod (left-tensor-product-by term other)))
364 (cond
365 ((r-zerop prod) nil)
366 (t (list prod)))))
367 (poly-termlist self)))
368 (incf (poly-dimension self) (monom-dimension other))
369 self)
370
371(defmethod right-tensor-product-by ((self poly) (other monom))
372 (setf (poly-termlist self)
373 (mapcan #'(lambda (term)
374 (let ((prod (right-tensor-product-by term other)))
375 (cond
376 ((r-zerop prod) nil)
377 (t (list prod)))))
378 (poly-termlist self)))
379 (incf (poly-dimension self) (monom-dimension other))
380 self)
381
382
383(defun standard-extension (plist &aux (k (length plist)) (i 0))
384 "Calculate [U1*P1,U2*P2,...,UK*PK], where PLIST=[P1,P2,...,PK]
385is a list of polynomials. Destructively modifies PLIST elements."
386 (mapc #'(lambda (poly)
387 (left-tensor-product-by
388 poly
389 (prog1
390 (make-monom-variable k i)
391 (incf i))))
392 plist))
393
394(defun standard-extension-1 (plist
395 &aux
396 (plist (standard-extension plist))
397 (nvars (poly-dimension (car plist))))
398 "Calculate [U1*P1-1,U2*P2-1,...,UK*PK-1], where PLIST=[P1,P2,...,PK].
399Firstly, new K variables U1, U2, ..., UK, are inserted into each
400polynomial. Subsequently, P1, P2, ..., PK are destructively modified
401tantamount to replacing PI with UI*PI-1. It assumes that all
402polynomials have the same dimension, and only the first polynomial
403is examined to determine this dimension."
404 ;; Implementation note: we use STANDARD-EXTENSION and then subtract
405 ;; 1 from each polynomial; since UI*PI has no constant term,
406 ;; we just need to append the constant term at the end
407 ;; of each termlist.
408 (flet ((subtract-1 (p)
409 (poly-append-term p (make-instance 'monom :dimension nvars) -1)))
410 (setf plist (mapc #'subtract-1 plist)))
411 plist)
412
413
414(defun standard-sum (plist
415 &aux
416 (plist (standard-extension plist))
417 (nvars (poly-dimension (car plist))))
418 "Calculate the polynomial U1*P1+U2*P2+...+UK*PK-1, where PLIST=[P1,P2,...,PK].
419Firstly, new K variables, U1, U2, ..., UK, are inserted into each
420polynomial. Subsequently, P1, P2, ..., PK are destructively modified
421tantamount to replacing PI with UI*PI, and the resulting polynomials
422are added. Finally, 1 is subtracted. It should be noted that the term
423order is not modified, which is equivalent to using a lexicographic
424order on the first K variables."
425 (flet ((subtract-1 (p)
426 (poly-append-term p (make-instance 'monom :dimension nvars) -1)))
427 (subtract-1
428 (make-instance
429 'poly
430 :termlist (apply #'nconc (mapcar #'poly-termlist plist))))))
431
432#|
433
434(defun saturation-extension-1 (ring f p)
435 "Calculate [F, U*P-1]. It destructively modifies F."
436 (declare (type ring ring))
437 (polysaturation-extension ring f (list p)))
438
439
440
441
442(defun spoly (ring-and-order f g
443 &aux
444 (ring (ro-ring ring-and-order)))
445 "It yields the S-polynomial of polynomials F and G."
446 (declare (type ring-and-order ring-and-order) (type poly f g))
447 (let* ((lcm (monom-lcm (poly-lm f) (poly-lm g)))
448 (mf (monom-div lcm (poly-lm f)))
449 (mg (monom-div lcm (poly-lm g))))
450 (declare (type monom mf mg))
451 (multiple-value-bind (c cf cg)
452 (funcall (ring-ezgcd ring) (poly-lc f) (poly-lc g))
453 (declare (ignore c))
454 (poly-sub
455 ring-and-order
456 (scalar-times-poly ring cg (monom-times-poly mf f))
457 (scalar-times-poly ring cf (monom-times-poly mg g))))))
458
459
460(defun poly-primitive-part (ring p)
461 "Divide polynomial P with integer coefficients by gcd of its
462coefficients and return the result."
463 (declare (type ring ring) (type poly p))
464 (if (poly-zerop p)
465 (values p 1)
466 (let ((c (poly-content ring p)))
467 (values (make-poly-from-termlist
468 (mapcar
469 #'(lambda (x)
470 (make-term :monom (term-monom x)
471 :coeff (funcall (ring-div ring) (term-coeff x) c)))
472 (poly-termlist p))
473 (poly-sugar p))
474 c))))
475
476(defun poly-content (ring p)
477 "Greatest common divisor of the coefficients of the polynomial P. Use the RING structure
478to compute the greatest common divisor."
479 (declare (type ring ring) (type poly p))
480 (reduce (ring-gcd ring) (mapcar #'term-coeff (rest (poly-termlist p))) :initial-value (poly-lc p)))
481
482|#
Note: See TracBrowser for help on using the repository browser.