close Warning: Can't synchronize with repository "(default)" (The repository directory has changed, you should resynchronize the repository with: trac-admin $ENV repository resync '(default)'). Look in the Trac log for more information.

source: branches/f4grobner/polynomial.lisp@ 1217

Last change on this file since 1217 was 1217, checked in by Marek Rychlik, 9 years ago

* empty log message *
File size: 15.4 KB
Line 
1;;; -*- Mode: Lisp -*-
2;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
3;;;
4;;; Copyright (C) 1999, 2002, 2009, 2015 Marek Rychlik <rychlik@u.arizona.edu>
5;;;
6;;; This program is free software; you can redistribute it and/or modify
7;;; it under the terms of the GNU General Public License as published by
8;;; the Free Software Foundation; either version 2 of the License, or
9;;; (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
19;;;
20;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
21
22
23(defpackage "POLYNOMIAL"
24 (:use :cl :ring :ring-and-order :monomial :order :term :termlist :infix)
25 (:export "POLY"
26 "POLY-TERMLIST"
27 "POLY-SUGAR"
28 "POLY-LT"
29 "MAKE-POLY-FROM-TERMLIST"
30 "MAKE-POLY-ZERO"
31 "MAKE-VARIABLE"
32 "POLY-UNIT"
33 "POLY-LM"
34 "POLY-SECOND-LM"
35 "POLY-SECOND-LT"
36 "POLY-LC"
37 "POLY-SECOND-LC"
38 "POLY-ZEROP"
39 "POLY-LENGTH"
40 "SCALAR-TIMES-POLY"
41 "SCALAR-TIMES-POLY-1"
42 "MONOM-TIMES-POLY"
43 "TERM-TIMES-POLY"
44 "POLY-ADD"
45 "POLY-SUB"
46 "POLY-UMINUS"
47 "POLY-MUL"
48 "POLY-EXPT"
49 "POLY-APPEND"
50 "POLY-NREVERSE"
51 "POLY-CONTRACT"
52 "POLY-EXTEND"
53 "POLY-ADD-VARIABLES"
54 "POLY-LIST-ADD-VARIABLES"
55 "POLY-STANDARD-EXTENSION"
56 "SATURATION-EXTENSION"
57 "POLYSATURATION-EXTENSION"
58 "SATURATION-EXTENSION-1"
59 "COERCE-COEFF"
60 "POLY-EVAL"
61 "POLY-EVAL-SCALAR"
62 "SPOLY"
63 "POLY-PRIMITIVE-PART"
64 "POLY-CONTENT"
65 "READ-INFIX-FORM"
66 "READ-POLY"
67 "STRING->POLY"
68 "POLY->ALIST"
69 "STRING->ALIST"
70 ))
71
72(in-package :polynomial)
73
74;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
75;;
76;; Polynomials
77;;
78;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
79
80(defstruct (poly
81 ;;
82 ;; BOA constructor, by default constructs zero polynomial
83 (:constructor make-poly-from-termlist (termlist &optional (sugar (termlist-sugar termlist))))
84 (:constructor make-poly-zero (&aux (termlist nil) (sugar -1)))
85 ;; Constructor of polynomials representing a variable
86 (:constructor make-variable (ring nvars pos &optional (power 1)
87 &aux
88 (termlist (list
89 (make-term-variable ring nvars pos power)))
90 (sugar power)))
91 (:constructor poly-unit (ring dimension
92 &aux
93 (termlist (termlist-unit ring dimension))
94 (sugar 0))))
95 (termlist nil :type list)
96 (sugar -1 :type fixnum))
97
98;; Leading term
99(defmacro poly-lt (p) `(car (poly-termlist ,p)))
100
101;; Second term
102(defmacro poly-second-lt (p) `(cadar (poly-termlist ,p)))
103
104;; Leading monomial
105(defun poly-lm (p) (term-monom (poly-lt p)))
106
107;; Second monomial
108(defun poly-second-lm (p) (term-monom (poly-second-lt p)))
109
110;; Leading coefficient
111(defun poly-lc (p) (term-coeff (poly-lt p)))
112
113;; Second coefficient
114(defun poly-second-lc (p) (term-coeff (poly-second-lt p)))
115
116;; Testing for a zero polynomial
117(defun poly-zerop (p) (null (poly-termlist p)))
118
119;; The number of terms
120(defun poly-length (p) (length (poly-termlist p)))
121
122(defun poly-reset-sugar (p)
123 "(Re)sets the sugar of a polynomial P to the sugar of (POLY-TERMLIST P).
124Thus, the sugar is set to the maximum sugar of all monomials of P, or -1
125if P is a zero polynomial."
126 (declare (type poly p))
127 (setf (poly-sugar p) (termlist-sugar (poly-termlist p)))
128 p)
129
130(defun scalar-times-poly (ring c p)
131 "The scalar product of scalar C by a polynomial P. The sugar of the
132original polynomial becomes the sugar of the result."
133 (declare (type ring ring) (type poly p))
134 (make-poly-from-termlist (scalar-times-termlist ring c (poly-termlist p)) (poly-sugar p)))
135
136(defun scalar-times-poly-1 (ring c p)
137 "The scalar product of scalar C by a polynomial P, omitting the head term. The sugar of the
138original polynomial becomes the sugar of the result."
139 (declare (type ring ring) (type poly p))
140 (make-poly-from-termlist (scalar-times-termlist ring c (cdr (poly-termlist p))) (poly-sugar p)))
141
142(defun monom-times-poly (m p)
143 (declare (type poly p))
144 (make-poly-from-termlist
145 (monom-times-termlist m (poly-termlist p))
146 (+ (poly-sugar p) (monom-sugar m))))
147
148(defun term-times-poly (ring term p)
149 (declare (type ring ring) (type term term) (type poly p))
150 (make-poly-from-termlist
151 (term-times-termlist ring term (poly-termlist p))
152 (+ (poly-sugar p) (term-sugar term))))
153
154(defun poly-add (ring-and-order p q)
155 (declare (type ring-and-order ring-and-order) (type poly p q))
156 (make-poly-from-termlist
157 (termlist-add ring-and-order
158 (poly-termlist p)
159 (poly-termlist q))
160 (max (poly-sugar p) (poly-sugar q))))
161
162(defun poly-sub (ring-and-order p q)
163 (declare (type ring-and-order ring-and-order) (type poly p q))
164 (make-poly-from-termlist
165 (termlist-sub ring-and-order (poly-termlist p) (poly-termlist q))
166 (max (poly-sugar p) (poly-sugar q))))
167
168(defun poly-uminus (ring p)
169 (declare (type ring ring) (type poly p))
170 (make-poly-from-termlist
171 (termlist-uminus ring (poly-termlist p))
172 (poly-sugar p)))
173
174(defun poly-mul (ring-and-order p q)
175 (declare (type ring-and-order ring-and-order) (type poly p q))
176 (make-poly-from-termlist
177 (termlist-mul ring-and-order (poly-termlist p) (poly-termlist q))
178 (+ (poly-sugar p) (poly-sugar q))))
179
180(defun poly-expt (ring-and-order p n)
181 (declare (type ring-and-order ring-and-order) (type poly p))
182 (make-poly-from-termlist (termlist-expt ring-and-order (poly-termlist p) n) (* n (poly-sugar p))))
183
184(defun poly-append (&rest plist)
185 (make-poly-from-termlist (apply #'append (mapcar #'poly-termlist plist))
186 (apply #'max (mapcar #'poly-sugar plist))))
187
188(defun poly-nreverse (p)
189 (declare (type poly p))
190 (setf (poly-termlist p) (nreverse (poly-termlist p)))
191 p)
192
193(defun poly-contract (p &optional (k 1))
194 (declare (type poly p))
195 (make-poly-from-termlist (termlist-contract (poly-termlist p) k)
196 (poly-sugar p)))
197
198(defun poly-extend (p &optional (m (make-monom :dimension 1)))
199 (declare (type poly p))
200 (make-poly-from-termlist
201 (termlist-extend (poly-termlist p) m)
202 (+ (poly-sugar p) (monom-sugar m))))
203
204(defun poly-add-variables (p k)
205 (declare (type poly p))
206 (setf (poly-termlist p) (termlist-add-variables (poly-termlist p) k))
207 p)
208
209(defun poly-list-add-variables (plist k)
210 (mapcar #'(lambda (p) (poly-add-variables p k)) plist))
211
212(defun poly-standard-extension (plist &aux (k (length plist)))
213 "Calculate [U1*P1,U2*P2,...,UK*PK], where PLIST=[P1,P2,...,PK]."
214 (declare (list plist) (fixnum k))
215 (labels ((incf-power (g i)
216 (dolist (x (poly-termlist g))
217 (incf (monom-elt (term-monom x) i)))
218 (incf (poly-sugar g))))
219 (setf plist (poly-list-add-variables plist k))
220 (dotimes (i k plist)
221 (incf-power (nth i plist) i))))
222
223(defun saturation-extension (ring f plist &aux (k (length plist)) (d (monom-dimension (poly-lm (car plist)))))
224 "Calculate [F, U1*P1-1,U2*P2-1,...,UK*PK-1], where PLIST=[P1,P2,...,PK]."
225 (setf f (poly-list-add-variables f k)
226 plist (mapcar #'(lambda (x)
227 (setf (poly-termlist x) (nconc (poly-termlist x)
228 (list (make-term (make-monom :dimension d)
229 (funcall (ring-uminus ring) (funcall (ring-unit ring)))))))
230 x)
231 (poly-standard-extension plist)))
232 (append f plist))
233
234
235(defun polysaturation-extension (ring f plist &aux (k (length plist))
236 (d (+ k (monom-dimension (poly-lm (car plist))))))
237 "Calculate [F, U1*P1+U2*P2+...+UK*PK-1], where PLIST=[P1,P2,...,PK]."
238 (setf f (poly-list-add-variables f k)
239 plist (apply #'poly-append (poly-standard-extension plist))
240 (cdr (last (poly-termlist plist))) (list (make-term (make-monom :dimension d)
241 (funcall (ring-uminus ring) (funcall (ring-unit ring))))))
242 (append f (list plist)))
243
244(defun saturation-extension-1 (ring f p) (polysaturation-extension ring f (list p)))
245
246;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
247;;
248;; Evaluation of polynomial (prefix) expressions
249;;
250;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
251
252(defun coerce-coeff (ring expr vars)
253 "Coerce an element of the coefficient ring to a constant polynomial."
254 ;; Modular arithmetic handler by rat
255 (make-poly-from-termlist (list (make-term (make-monom :dimension (length vars))
256 (funcall (ring-parse ring) expr)))
257 0))
258
259(defun poly-eval (expr vars
260 &optional
261 (ring *ring-of-integers*)
262 (order #'lex>)
263 (list-marker :[)
264 &aux
265 (ring-and-order (make-ring-and-order :ring ring :order order)))
266 "Evaluate Lisp form EXPR to a polynomial or a list of polynomials in
267variables VARS. Return the resulting polynomial or list of
268polynomials. Standard arithmetical operators in form EXPR are
269replaced with their analogues in the ring of polynomials, and the
270resulting expression is evaluated, resulting in a polynomial or a list
271of polynomials in internal form. A similar operation in another computer
272algebra system could be called 'expand' or so."
273 (labels ((p-eval (arg) (poly-eval arg vars ring order))
274 (p-eval-scalar (arg) (poly-eval-scalar arg))
275 (p-eval-list (args) (mapcar #'p-eval args))
276 (p-add (x y) (poly-add ring-and-order x y)))
277 (cond
278 ((null expr) (error "Empty expression"))
279 ((eql expr 0) (make-poly-zero))
280 ((member expr vars :test #'equalp)
281 (let ((pos (position expr vars :test #'equalp)))
282 (make-variable ring (length vars) pos)))
283 ((atom expr)
284 (coerce-coeff ring expr vars))
285 ((eq (car expr) list-marker)
286 (cons list-marker (p-eval-list (cdr expr))))
287 (t
288 (case (car expr)
289 (+ (reduce #'p-add (p-eval-list (cdr expr))))
290 (- (case (length expr)
291 (1 (make-poly-zero))
292 (2 (poly-uminus ring (p-eval (cadr expr))))
293 (3 (poly-sub ring-and-order (p-eval (cadr expr)) (p-eval (caddr expr))))
294 (otherwise (poly-sub ring-and-order (p-eval (cadr expr))
295 (reduce #'p-add (p-eval-list (cddr expr)))))))
296 (*
297 (if (endp (cddr expr)) ;unary
298 (p-eval (cdr expr))
299 (reduce #'(lambda (p q) (poly-mul ring-and-order p q)) (p-eval-list (cdr expr)))))
300 (/
301 ;; A polynomial can be divided by a scalar
302 (cond
303 ((endp (cddr expr))
304 ;; A special case (/ ?), the inverse
305 (coerce-coeff ring (apply (ring-div ring) (cdr expr)) vars))
306 (t
307 (let ((num (p-eval (cadr expr)))
308 (denom-inverse (apply (ring-div ring)
309 (cons (funcall (ring-unit ring))
310 (mapcar #'p-eval-scalar (cddr expr))))))
311 (scalar-times-poly ring denom-inverse num)))))
312 (expt
313 (cond
314 ((member (cadr expr) vars :test #'equalp)
315 ;;Special handling of (expt var pow)
316 (let ((pos (position (cadr expr) vars :test #'equalp)))
317 (make-variable ring (length vars) pos (caddr expr))))
318 ((not (and (integerp (caddr expr)) (plusp (caddr expr))))
319 ;; Negative power means division in coefficient ring
320 ;; Non-integer power means non-polynomial coefficient
321 (coerce-coeff ring expr vars))
322 (t (poly-expt ring-and-order (p-eval (cadr expr)) (caddr expr)))))
323 (otherwise
324 (coerce-coeff ring expr vars)))))))
325
326(defun poly-eval-scalar (expr
327 &optional
328 (ring *ring-of-integers*)
329 &aux
330 (order #'lex>))
331 "Evaluate a scalar expression EXPR in ring RING."
332 (poly-lc (poly-eval expr nil ring order)))
333
334(defun spoly (ring-and-order f g
335 &aux
336 (ring (ro-ring ring-and-order)))
337 "It yields the S-polynomial of polynomials F and G."
338 (declare (type poly f g))
339 (let* ((lcm (monom-lcm (poly-lm f) (poly-lm g)))
340 (mf (monom-div lcm (poly-lm f)))
341 (mg (monom-div lcm (poly-lm g))))
342 (declare (type monom mf mg))
343 (multiple-value-bind (c cf cg)
344 (funcall (ring-ezgcd ring) (poly-lc f) (poly-lc g))
345 (declare (ignore c))
346 (poly-sub
347 ring-and-order
348 (scalar-times-poly ring cg (monom-times-poly mf f))
349 (scalar-times-poly ring cf (monom-times-poly mg g))))))
350
351
352(defun poly-primitive-part (ring p)
353 "Divide polynomial P with integer coefficients by gcd of its
354coefficients and return the result."
355 (declare (type poly p))
356 (if (poly-zerop p)
357 (values p 1)
358 (let ((c (poly-content ring p)))
359 (values (make-poly-from-termlist
360 (mapcar
361 #'(lambda (x)
362 (make-term (term-monom x)
363 (funcall (ring-div ring) (term-coeff x) c)))
364 (poly-termlist p))
365 (poly-sugar p))
366 c))))
367
368(defun poly-content (ring p)
369 "Greatest common divisor of the coefficients of the polynomial P. Use the RING structure
370to compute the greatest common divisor."
371 (declare (type poly p))
372 (reduce (ring-gcd ring) (mapcar #'term-coeff (rest (poly-termlist p))) :initial-value (poly-lc p)))
373
374(defun read-infix-form (&key (stream t))
375 "Parser of infix expressions with integer/rational coefficients
376The parser will recognize two kinds of polynomial expressions:
377
378- polynomials in fully expanded forms with coefficients
379 written in front of symbolic expressions; constants can be optionally
380 enclosed in (); for example, the infix form
381 X^2-Y^2+(-4/3)*U^2*W^3-5
382 parses to
383 (+ (- (EXPT X 2) (EXPT Y 2)) (* (- (/ 4 3)) (EXPT U 2) (EXPT W 3)) (- 5))
384
385- lists of polynomials; for example
386 [X-Y, X^2+3*Z]
387 parses to
388 (:[ (- X Y) (+ (EXPT X 2) (* 3 Z)))
389 where the first symbol [ marks a list of polynomials.
390
391-other infix expressions, for example
392 [(X-Y)*(X+Y)/Z,(X+1)^2]
393parses to:
394 (:[ (/ (* (- X Y) (+ X Y)) Z) (EXPT (+ X 1) 2))
395Currently this function is implemented using M. Kantrowitz's INFIX package."
396 (read-from-string
397 (concatenate 'string
398 "#I("
399 (with-output-to-string (s)
400 (loop
401 (multiple-value-bind (line eof)
402 (read-line stream t)
403 (format s "~A" line)
404 (when eof (return)))))
405 ")")))
406
407(defun read-poly (vars &key
408 (stream t)
409 (ring *ring-of-integers*)
410 (order #'lex>))
411 "Reads an expression in prefix form from a stream STREAM.
412The expression read from the strem should represent a polynomial or a
413list of polynomials in variables VARS, over the ring RING. The
414polynomial or list of polynomials is returned, with terms in each
415polynomial ordered according to monomial order ORDER."
416 (poly-eval (read-infix-form :stream stream) vars ring order))
417
418(defun string->poly (str vars
419 &optional
420 (ring *ring-of-integers*)
421 (order #'lex>))
422 "Converts a string STR to a polynomial in variables VARS."
423 (with-input-from-string (s str)
424 (read-poly vars :stream s :ring ring :order order)))
425
426(defun poly->alist (p)
427 "Convert a polynomial P to an association list. Thus, the format of the
428returned value is ((MONOM[0] . COEFF[0]) (MONOM[1] . COEFF[1]) ...), where
429MONOM[I] is a list of exponents in the monomial and COEFF[I] is the
430corresponding coefficient in the ring."
431 (cond
432 ((poly-p p)
433 (mapcar #'term->cons (poly-termlist p)))
434 ((and (consp p) (eq (car p) :[))
435 (cons :[ (mapcar #'poly->alist (cdr p))))))
436
437(defun string->alist (str vars
438 &optional
439 (ring *ring-of-integers*)
440 (order #'lex>))
441 "Convert a string STR representing a polynomial or polynomial list to
442an association list (... (MONOM . COEFF) ...)."
443 (poly->alist (string->poly str vars ring order)))
Note: See TracBrowser for help on using the repository browser.