close Warning: Can't synchronize with repository "(default)" (The repository directory has changed, you should resynchronize the repository with: trac-admin $ENV repository resync '(default)'). Look in the Trac log for more information.

source: branches/f4grobner/mx-grobner.lisp@ 1694

Last change on this file since 1694 was 1694, checked in by Marek Rychlik, 9 years ago

* empty log message *
File size: 20.1 KB
Line 
1;;; -*- Mode: Lisp -*-
2;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
3;;;
4;;; Copyright (C) 1999, 2002, 2009, 2015 Marek Rychlik <rychlik@u.arizona.edu>
5;;;
6;;; This program is free software; you can redistribute it and/or modify
7;;; it under the terms of the GNU General Public License as published by
8;;; the Free Software Foundation; either version 2 of the License, or
9;;; (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
19;;;
20;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
21
22;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
23;;
24;; Load this file into Maxima to bootstrap the Grobner package.
25;; NOTE: This file does use symbols defined by Maxima, so it
26;; will not work when loaded in Common Lisp.
27;;
28;; DETAILS: This file implements an interface between the Grobner
29;; basis package NGROBNER, which is a pure Common Lisp package, and
30;; Maxima. NGROBNER for efficiency uses its own representation of
31;; polynomials. Thus, it is necessary to convert Maxima representation
32;; to the internal representation and back. The facilities to do so
33;; are implemented in this file.
34;;
35;; Also, since the NGROBNER package consists of many Lisp files, it is
36;; necessary to load the files. It is possible and preferrable to use
37;; ASDF for this purpose. The default is ASDF. It is also possible to
38;; simply used LOAD and COMPILE-FILE to accomplish this task.
39;;
40;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
41
42(in-package :maxima)
43
44(macsyma-module cgb-maxima)
45
46
47(eval-when
48 #+gcl (load eval)
49 #-gcl (:load-toplevel :execute)
50 (format t "~&Loading maxima-grobner ~a ~a~%"
51 "$Revision: 2.0 $" "$Date: 2015/06/02 0:34:17 $"))
52
53;;FUNCTS is loaded because it contains the definition of LCM
54($load "functs")
55#+sbcl(progn (require 'asdf) (load "ngrobner.asd")(asdf:load-system :ngrobner))
56
57(use-package :ngrobner)
58
59
60;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
61;;
62;; Maxima expression ring
63;;
64;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
65;;
66;; This is how we perform operations on coefficients
67;; using Maxima functions.
68;;
69;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
70
71(defparameter +maxima-ring+
72 (make-ring
73 ;;(defun coeff-zerop (expr) (meval1 `(($is) (($equal) ,expr 0))))
74 :parse #'(lambda (expr)
75 (when modulus (setf expr ($rat expr)))
76 expr)
77 :unit #'(lambda () (if modulus ($rat 1) 1))
78 :zerop #'(lambda (expr)
79 ;;When is exactly a maxima expression equal to 0?
80 (cond ((numberp expr)
81 (= expr 0))
82 ((atom expr) nil)
83 (t
84 (case (caar expr)
85 (mrat (eql ($ratdisrep expr) 0))
86 (otherwise (eql ($totaldisrep expr) 0))))))
87 :add #'(lambda (x y) (m+ x y))
88 :sub #'(lambda (x y) (m- x y))
89 :uminus #'(lambda (x) (m- x))
90 :mul #'(lambda (x y) (m* x y))
91 ;;(defun coeff-div (x y) (cadr ($divide x y)))
92 :div #'(lambda (x y) (m// x y))
93 :lcm #'(lambda (x y) (meval1 `((|$LCM|) ,x ,y)))
94 :ezgcd #'(lambda (x y) (apply #'values (cdr ($ezgcd ($totaldisrep x) ($totaldisrep y)))))
95 ;; :gcd #'(lambda (x y) (second ($ezgcd x y)))))
96 :gcd #'(lambda (x y) ($gcd x y))))
97
98;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
99;;
100;; Maxima expression parsing
101;;
102;;
103;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
104;;
105;; Functions and macros dealing with internal representation
106;; structure.
107;;
108;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
109
110(defun equal-test-p (expr1 expr2)
111 (alike1 expr1 expr2))
112
113(defun coerce-maxima-list (expr)
114 "Convert a Maxima list to Lisp list."
115 (cond
116 ((and (consp (car expr)) (eql (caar expr) 'mlist)) (cdr expr))
117 (t expr)))
118
119(defun free-of-vars (expr vars) (apply #'$freeof `(,@vars ,expr)))
120
121;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
122;;
123;; Order utilities
124;;
125;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
126
127(defun find-ring-by-name (ring)
128 "This function returns the ring structure bases on input symbol."
129 (cond
130 ((null ring) nil)
131 ((symbolp ring)
132 (case ring
133 ((maxima-ring :maxima-ring #:maxima-ring $expression_ring #:expression_ring)
134 +maxima-ring+)
135 ((ring-of-integers :ring-of-integers #:ring-of-integers $ring_of_integers) +ring-of-integers+)
136 (otherwise
137 (mtell "~%Warning: Ring ~M not found. Using default.~%" ring))))
138 (t
139 (mtell "~%Ring specification ~M is not recognized. Using default.~%" ring)
140 nil)))
141
142(defun find-order-by-name (order)
143 "This function returns the order function bases on its name."
144 (cond
145 ((null order) nil)
146 ((symbolp order)
147 (case order
148 ((lex :lex $lex #:lex)
149 #'lex>)
150 ((grlex :grlex $grlex #:grlex)
151 #'grlex>)
152 ((grevlex :grevlex $grevlex #:grevlex)
153 #'grevlex>)
154 ((invlex :invlex $invlex #:invlex)
155 #'invlex>)
156 (otherwise
157 (mtell "~%Warning: Order ~M not found. Using default.~%" order))))
158 (t
159 (mtell "~%Order specification ~M is not recognized. Using default.~%" order)
160 nil)))
161
162(defun maxima->poly (expr vars
163 &optional
164 (ring (find-ring-by-name $poly_coefficient_ring))
165 (order (find-order-by-name $poly_monomial_order))
166 (primary-elimination-order (find-order-by-name $poly_primary_elimination_order))
167 (secondary-elimination-order (find-order-by-name $poly_secondary_elimination_order))
168 &aux
169 (vars (coerce-maxima-list vars))
170 (ring-and-order (make-ring-and-order
171 :ring ring
172 :order order
173 :primary-elimination-order primary-elimination-order
174 :secondary-elimination-order secondary-elimination-order))
175 (ring (ro-ring ring-and-order)))
176 "Convert a maxima polynomial expression EXPR in variables VARS to
177internal form. This works by first converting the expression to Lisp,
178and then evaluating the expression using polynomial arithmetic
179implemented by the POLYNOMIAL package."
180 (labels ((parse (arg) (maxima->poly arg vars
181 ring
182 order
183 primary-elimination-order
184 secondary-elimination-order))
185 (parse-list (args) (mapcar #'parse args)))
186 (cond
187 ((eql expr 0) (make-poly-zero))
188 ((member expr vars :test #'equal-test-p)
189 (let ((pos (position expr vars :test #'equal-test-p)))
190 (make-poly-variable (ro-ring ring-and-order) (length vars) pos)))
191 ((free-of-vars expr vars)
192 ;;This means that variable-free CRE and Poisson forms will be converted
193 ;;to coefficients intact
194 (coerce-coeff (ro-ring ring-and-order) expr vars))
195 (t
196 (case (caar expr)
197 (mplus (reduce #'(lambda (x y) (poly-add ring-and-order x y)) (parse-list (cdr expr))))
198 (mminus (poly-uminus (ro-ring ring-and-order) (parse (cadr expr))))
199 (mtimes
200 (if (endp (cddr expr)) ;unary
201 (parse (cdr expr))
202 (reduce #'(lambda (p q) (poly-mul ring-and-order p q)) (parse-list (cdr expr)))))
203 (mexpt
204 (cond
205 ((member (cadr expr) vars :test #'equal-test-p)
206 ;;Special handling of (expt var pow)
207 (let ((pos (position (cadr expr) vars :test #'equal-test-p)))
208 (make-poly-variable (ro-ring ring-and-order) (length vars) pos (caddr expr))))
209 ((not (and (integerp (caddr expr)) (plusp (caddr expr))))
210 ;; Negative power means division in coefficient ring
211 ;; Non-integer power means non-polynomial coefficient
212 (mtell "~%Warning: Expression ~%~M~%contains power which is not a positive integer. Parsing as coefficient.~%"
213 expr)
214 (coerce-coeff (ro-ring ring-and-order) expr vars))
215 (t (poly-expt (ro-ring ring-and-order) (parse (cadr expr)) (caddr expr)))))
216 (mrat (parse ($ratdisrep expr)))
217 (mpois (parse ($outofpois expr)))
218 (otherwise
219 (coerce-coeff (ro-ring ring-and-order) expr vars)))))))
220
221(defun maxima->pl (expr vars
222 &optional
223 (ring (find-ring-by-name $poly_coefficient_ring))
224 (order (find-order-by-name $poly_monomial_order))
225 (primary-elimination-order (find-order-by-name $poly_primary_elimination_order))
226 (secondary-elimination-order (find-order-by-name $poly_secondary_elimination_order)))
227 "Convert a Maxima representation of a list of polynomials to the internal form."
228 (case (caar expr)
229 (mlist (mapcar #'(lambda (p)
230 (maxima->poly p vars
231 ring order
232 primary-elimination-order
233 secondary-elimination-order))
234 (cdr expr)))
235 (otherwise (merror "Expression ~M is not a list of polynomials in variables ~M."
236 expr vars))))
237
238(defun maxima->pll (poly-list-list vars)
239 "Parse a Maxima representation of a list of lists of polynomials."
240 (mapcar #'(lambda (g) (parse-poly-list g vars)) (coerce-maxima-list poly-list-list)))
241
242
243
244
245;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
246;;
247;; Conversion from internal form to Maxima general form
248;;
249;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
250
251(defun maxima-head ()
252 (if $poly_return_term_list
253 '(mlist)
254 '(mplus)))
255
256(defun coerce-to-maxima (poly-type object vars)
257 (case poly-type
258 (:polynomial
259 `(,(maxima-head) ,@(mapcar #'(lambda (term) (coerce-to-maxima :term term vars)) (poly-termlist object))))
260 (:poly-list
261 `((mlist) ,@(mapcar #'(lambda (p) (funcall *ratdisrep-fun* (coerce-to-maxima :polynomial p vars))) object)))
262 (:term
263 `((mtimes) ,(funcall *ratdisrep-fun* (term-coeff object))
264 ,@(mapcar #'(lambda (var power) `((mexpt) ,var ,power))
265 vars (coerce (term-monom object) 'list))))
266 ;; Assumes that Lisp and Maxima logicals coincide
267 (:logical object)
268 (otherwise
269 object)))
270
271
272;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
273;;
274;; Unary and binary operation definition facility
275;;
276;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
277
278(defmacro define-unop (maxima-name fun-name
279 &optional (documentation nil documentation-supplied-p))
280 "Define a MAXIMA-level unary operator MAXIMA-NAME corresponding to unary function FUN-NAME."
281 `(defun ,maxima-name (p vars
282 &aux
283 (vars (coerce-maxima-list vars))
284 (p (parse-poly p vars)))
285 ,@(when documentation-supplied-p (list documentation))
286 (coerce-to-maxima :polynomial (,fun-name +maxima-ring+ p) vars)))
287
288(defmacro define-binop (maxima-name fun-name
289 &optional (documentation nil documentation-supplied-p))
290 "Define a MAXIMA-level binary operator MAXIMA-NAME corresponding to binary function FUN-NAME."
291 `(defmfun ,maxima-name (p q vars
292 &aux
293 (vars (coerce-maxima-list vars))
294 (p (parse-poly p vars))
295 (q (parse-poly q vars)))
296 ,@(when documentation-supplied-p (list documentation))
297 (coerce-to-maxima :polynomial (,fun-name +maxima-ring+ p q) vars)))
298
299
300;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
301;;
302;; Facilities for evaluating Grobner package expressions
303;; within a prepared environment
304;;
305;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
306
307(defmacro with-monomial-order ((order) &body body)
308 "Evaluate BODY with monomial order set to ORDER."
309 `(let ((*monomial-order* (or (find-order ,order) *monomial-order*)))
310 . ,body))
311
312(defmacro with-coefficient-ring ((ring) &body body)
313 "Evaluate BODY with coefficient ring set to RING."
314 `(let ((+maxima-ring+ (or (find-ring ,ring) +maxima-ring+)))
315 . ,body))
316
317(defmacro with-ring-and-order ((ring order) &body body)
318 "Evaluate BODY with monomial order set to ORDER and coefficient ring set to RING."
319 `(let ((*monomial-order* (or (find-order ,order) *monomial-order*))
320 (+maxima-ring+ (or (find-ring ,ring) +maxima-ring+)))
321 . ,body))
322
323(defmacro with-elimination-orders ((primary secondary elimination-order)
324 &body body)
325 "Evaluate BODY with primary and secondary elimination orders set to PRIMARY and SECONDARY."
326 `(let ((*primary-elimination-order* (or (find-order ,primary) *primary-elimination-order*))
327 (*secondary-elimination-order* (or (find-order ,secondary) *secondary-elimination-order*))
328 (*elimination-order* (or (find-order ,elimination-order) *elimination-order*)))
329 . ,body))
330
331
332;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
333;;
334;; Maxima-level interface functions
335;;
336;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
337
338;; Auxillary function for removing zero polynomial
339(defun remzero (plist) (remove #'poly-zerop plist))
340
341;;Simple operators
342
343(define-binop $poly_add poly-add
344 "Adds two polynomials P and Q")
345
346(define-binop $poly_subtract poly-sub
347 "Subtracts a polynomial Q from P.")
348
349(define-binop $poly_multiply poly-mul
350 "Returns the product of polynomials P and Q.")
351
352(define-binop $poly_s_polynomial spoly
353 "Returns the syzygy polynomial (S-polynomial) of two polynomials P and Q.")
354
355(define-unop $poly_primitive_part poly-primitive-part
356 "Returns the polynomial P divided by GCD of its coefficients.")
357
358(define-unop $poly_normalize poly-normalize
359 "Returns the polynomial P divided by the leading coefficient.")
360
361;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
362;;
363;; Macro facility for writing Maxima-level wrappers for
364;; functions operating on internal representation
365;;
366;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
367
368(defmacro with-parsed-polynomials (((maxima-vars &optional (maxima-new-vars nil new-vars-supplied-p))
369 &key (polynomials nil)
370 (poly-lists nil)
371 (poly-list-lists nil)
372 (value-type nil))
373 &body body
374 &aux (vars (gensym))
375 (new-vars (gensym)))
376 `(let ((,vars (coerce-maxima-list ,maxima-vars))
377 ,@(when new-vars-supplied-p
378 (list `(,new-vars (coerce-maxima-list ,maxima-new-vars)))))
379 (coerce-to-maxima
380 ,value-type
381 (with-coefficient-ring ($poly_coefficient_ring)
382 (with-monomial-order ($poly_monomial_order)
383 (with-elimination-orders ($poly_primary_elimination_order
384 $poly_secondary_elimination_order
385 $poly_elimination_order)
386 (let ,(let ((args nil))
387 (dolist (p polynomials args)
388 (setf args (cons `(,p (parse-poly ,p ,vars)) args)))
389 (dolist (p poly-lists args)
390 (setf args (cons `(,p (parse-poly-list ,p ,vars)) args)))
391 (dolist (p poly-list-lists args)
392 (setf args (cons `(,p (parse-poly-list-list ,p ,vars)) args))))
393 . ,body))))
394 ,(if new-vars-supplied-p
395 `(append ,vars ,new-vars)
396 vars))))
397
398
399;;Functions
400
401(defmfun $poly_expand (p vars)
402 "This function is equivalent to EXPAND(P) if P parses correctly to a polynomial.
403If the representation is not compatible with a polynomial in variables VARS,
404the result is an error."
405 (with-parsed-polynomials ((vars) :polynomials (p)
406 :value-type :polynomial)
407 p))
408
409(defmfun $poly_expt (p n vars)
410 (with-parsed-polynomials ((vars) :polynomials (p) :value-type :polynomial)
411 (poly-expt +maxima-ring+ p n)))
412
413(defmfun $poly_content (p vars)
414 (with-parsed-polynomials ((vars) :polynomials (p))
415 (poly-content +maxima-ring+ p)))
416
417(defmfun $poly_pseudo_divide (f fl vars
418 &aux (vars (coerce-maxima-list vars))
419 (f (parse-poly f vars))
420 (fl (parse-poly-list fl vars)))
421 (multiple-value-bind (quot rem c division-count)
422 (poly-pseudo-divide +maxima-ring+ f fl)
423 `((mlist)
424 ,(coerce-to-maxima :poly-list quot vars)
425 ,(coerce-to-maxima :polynomial rem vars)
426 ,c
427 ,division-count)))
428
429(defmfun $poly_exact_divide (f g vars)
430 (with-parsed-polynomials ((vars) :polynomials (f g) :value-type :polynomial)
431 (poly-exact-divide +maxima-ring+ f g)))
432
433(defmfun $poly_normal_form (f fl vars)
434 (with-parsed-polynomials ((vars) :polynomials (f)
435 :poly-lists (fl)
436 :value-type :polynomial)
437 (normal-form +maxima-ring+ f (remzero fl) nil)))
438
439(defmfun $poly_buchberger_criterion (g vars)
440 (with-parsed-polynomials ((vars) :poly-lists (g) :value-type :logical)
441 (buchberger-criterion +maxima-ring+ g)))
442
443(defmfun $poly_buchberger (fl vars)
444 (with-parsed-polynomials ((vars) :poly-lists (fl) :value-type :poly-list)
445 (buchberger +maxima-ring+ (remzero fl) 0 nil)))
446
447(defmfun $poly_reduction (plist vars)
448 (with-parsed-polynomials ((vars) :poly-lists (plist)
449 :value-type :poly-list)
450 (reduction +maxima-ring+ plist)))
451
452(defmfun $poly_minimization (plist vars)
453 (with-parsed-polynomials ((vars) :poly-lists (plist)
454 :value-type :poly-list)
455 (minimization plist)))
456
457(defmfun $poly_normalize_list (plist vars)
458 (with-parsed-polynomials ((vars) :poly-lists (plist)
459 :value-type :poly-list)
460 (poly-normalize-list +maxima-ring+ plist)))
461
462(defmfun $poly_grobner (f vars)
463 (with-parsed-polynomials ((vars) :poly-lists (f)
464 :value-type :poly-list)
465 (grobner +maxima-ring+ (remzero f))))
466
467(defmfun $poly_reduced_grobner (f vars)
468 (with-parsed-polynomials ((vars) :poly-lists (f)
469 :value-type :poly-list)
470 (reduced-grobner +maxima-ring+ (remzero f))))
471
472(defmfun $poly_depends_p (p var mvars
473 &aux (vars (coerce-maxima-list mvars))
474 (pos (position var vars)))
475 (if (null pos)
476 (merror "~%Variable ~M not in the list of variables ~M." var mvars)
477 (poly-depends-p (parse-poly p vars) pos)))
478
479(defmfun $poly_elimination_ideal (flist k vars)
480 (with-parsed-polynomials ((vars) :poly-lists (flist)
481 :value-type :poly-list)
482 (elimination-ideal +maxima-ring+ flist k nil 0)))
483
484(defmfun $poly_colon_ideal (f g vars)
485 (with-parsed-polynomials ((vars) :poly-lists (f g) :value-type :poly-list)
486 (colon-ideal +maxima-ring+ f g nil)))
487
488(defmfun $poly_ideal_intersection (f g vars)
489 (with-parsed-polynomials ((vars) :poly-lists (f g) :value-type :poly-list)
490 (ideal-intersection +maxima-ring+ f g nil)))
491
492(defmfun $poly_lcm (f g vars)
493 (with-parsed-polynomials ((vars) :polynomials (f g) :value-type :polynomial)
494 (poly-lcm +maxima-ring+ f g)))
495
496(defmfun $poly_gcd (f g vars)
497 ($first ($divide (m* f g) ($poly_lcm f g vars))))
498
499(defmfun $poly_grobner_equal (g1 g2 vars)
500 (with-parsed-polynomials ((vars) :poly-lists (g1 g2))
501 (grobner-equal +maxima-ring+ g1 g2)))
502
503(defmfun $poly_grobner_subsetp (g1 g2 vars)
504 (with-parsed-polynomials ((vars) :poly-lists (g1 g2))
505 (grobner-subsetp +maxima-ring+ g1 g2)))
506
507(defmfun $poly_grobner_member (p g vars)
508 (with-parsed-polynomials ((vars) :polynomials (p) :poly-lists (g))
509 (grobner-member +maxima-ring+ p g)))
510
511(defmfun $poly_ideal_saturation1 (f p vars)
512 (with-parsed-polynomials ((vars) :poly-lists (f) :polynomials (p)
513 :value-type :poly-list)
514 (ideal-saturation-1 +maxima-ring+ f p 0)))
515
516(defmfun $poly_saturation_extension (f plist vars new-vars)
517 (with-parsed-polynomials ((vars new-vars)
518 :poly-lists (f plist)
519 :value-type :poly-list)
520 (saturation-extension +maxima-ring+ f plist)))
521
522(defmfun $poly_polysaturation_extension (f plist vars new-vars)
523 (with-parsed-polynomials ((vars new-vars)
524 :poly-lists (f plist)
525 :value-type :poly-list)
526 (polysaturation-extension +maxima-ring+ f plist)))
527
528(defmfun $poly_ideal_polysaturation1 (f plist vars)
529 (with-parsed-polynomials ((vars) :poly-lists (f plist)
530 :value-type :poly-list)
531 (ideal-polysaturation-1 +maxima-ring+ f plist 0 nil)))
532
533(defmfun $poly_ideal_saturation (f g vars)
534 (with-parsed-polynomials ((vars) :poly-lists (f g)
535 :value-type :poly-list)
536 (ideal-saturation +maxima-ring+ f g 0 nil)))
537
538(defmfun $poly_ideal_polysaturation (f ideal-list vars)
539 (with-parsed-polynomials ((vars) :poly-lists (f)
540 :poly-list-lists (ideal-list)
541 :value-type :poly-list)
542 (ideal-polysaturation +maxima-ring+ f ideal-list 0 nil)))
543
544(defmfun $poly_lt (f vars)
545 (with-parsed-polynomials ((vars) :polynomials (f) :value-type :polynomial)
546 (make-poly-from-termlist (list (poly-lt f)))))
547
548(defmfun $poly_lm (f vars)
549 (with-parsed-polynomials ((vars) :polynomials (f) :value-type :polynomial)
550 (make-poly-from-termlist (list (make-term (poly-lm f) (funcall (ring-unit +maxima-ring+)))))))
551
552|#
Note: See TracBrowser for help on using the repository browser.