close Warning: Can't synchronize with repository "(default)" (The repository directory has changed, you should resynchronize the repository with: trac-admin $ENV repository resync '(default)'). Look in the Trac log for more information.

source: branches/f4grobner/monomial.lisp@ 1485

Last change on this file since 1485 was 1201, checked in by Marek Rychlik, 9 years ago

Changed the first line to eliminate 'unsafe' Emacs variables
File size: 7.3 KB
Line 
1;;; -*- Mode: Lisp -*-
2;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
3;;;
4;;; Copyright (C) 1999, 2002, 2009, 2015 Marek Rychlik <rychlik@u.arizona.edu>
5;;;
6;;; This program is free software; you can redistribute it and/or modify
7;;; it under the terms of the GNU General Public License as published by
8;;; the Free Software Foundation; either version 2 of the License, or
9;;; (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
19;;;
20;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
21
22;;----------------------------------------------------------------
23;; This package implements BASIC OPERATIONS ON MONOMIALS
24;;----------------------------------------------------------------
25;; DATA STRUCTURES: Conceptually, monomials can be represented as lists:
26;;
27;; monom: (n1 n2 ... nk) where ni are non-negative integers
28;;
29;; However, lists may be implemented as other sequence types,
30;; so the flexibility to change the representation should be
31;; maintained in the code to use general operations on sequences
32;; whenever possible. The optimization for the actual representation
33;; should be left to declarations and the compiler.
34;;----------------------------------------------------------------
35;; EXAMPLES: Suppose that variables are x and y. Then
36;;
37;; Monom x*y^2 ---> (1 2)
38;;
39;;----------------------------------------------------------------
40
41(defpackage "MONOMIAL"
42 (:use :cl)
43 (:export "MONOM"
44 "EXPONENT"
45 "MAKE-MONOM"
46 "MAKE-MONOM-VARIABLE"
47 "MONOM-ELT"
48 "MONOM-DIMENSION"
49 "MONOM-TOTAL-DEGREE"
50 "MONOM-SUGAR"
51 "MONOM-DIV"
52 "MONOM-MUL"
53 "MONOM-DIVIDES-P"
54 "MONOM-DIVIDES-MONOM-LCM-P"
55 "MONOM-LCM-DIVIDES-MONOM-LCM-P"
56 "MONOM-LCM-EQUAL-MONOM-LCM-P"
57 "MONOM-DIVISIBLE-BY-P"
58 "MONOM-REL-PRIME-P"
59 "MONOM-EQUAL-P"
60 "MONOM-LCM"
61 "MONOM-GCD"
62 "MONOM-DEPENDS-P"
63 "MONOM-MAP"
64 "MONOM-APPEND"
65 "MONOM-CONTRACT"
66 "MONOM->LIST"))
67
68(in-package :monomial)
69
70(deftype exponent ()
71 "Type of exponent in a monomial."
72 'fixnum)
73
74(deftype monom (&optional dim)
75 "Type of monomial."
76 `(simple-array exponent (,dim)))
77
78;; If a monomial is redefined as structure with slot EXPONENTS, the function
79;; below can be the BOA constructor.
80(defun make-monom (&key
81 (dimension nil dimension-suppied-p)
82 (initial-exponents nil initial-exponents-supplied-p)
83 (initial-exponent nil initial-exponent-supplied-p)
84 &aux
85 (dim (cond (dimension-suppied-p dimension)
86 (initial-exponents-supplied-p (length initial-exponents))
87 (t (error "You must provide DIMENSION nor INITIAL-EXPONENTS"))))
88 (monom (cond
89 ;; when exponents are supplied
90 (initial-exponents-supplied-p
91 (make-array (list dim) :initial-contents initial-exponents
92 :element-type 'exponent))
93 ;; when all exponents are to be identical
94 (initial-exponent-supplied-p
95 (make-array (list dim) :initial-element initial-exponent
96 :element-type 'exponent))
97 ;; otherwise, all exponents are zero
98 (t
99 (make-array (list dim) :element-type 'exponent :initial-element 0)))))
100 "A constructor of monomials. If DIMENSION is given, a sequence of DIMENSION elements of type EXPONENT is constructed,
101where individual elements are the value of INITIAL-EXPONENT, which
102defaults to 0. Alternatively, all elements may be specified as a list
103INITIAL-EXPONENTS."
104 monom)
105
106
107;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
108;;
109;; Operations on monomials
110;;
111;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
112
113(defun monom-dimension (m)
114 (length m))
115
116(defmacro monom-elt (m index)
117 "Return the power in the monomial M of variable number INDEX."
118 `(elt ,m ,index))
119
120(defun monom-total-degree (m &optional (start 0) (end (monom-dimension m)))
121 "Return the todal degree of a monomoal M. Optinally, a range
122of variables may be specified with arguments START and END."
123 (reduce #'+ m :start start :end end))
124
125(defun monom-sugar (m &aux (start 0) (end (monom-dimension m)))
126 "Return the sugar of a monomial M. Optinally, a range
127of variables may be specified with arguments START and END."
128 (monom-total-degree m start end))
129
130(defun monom-div (m1 m2 &aux (result (copy-seq m1)))
131 "Divide monomial M1 by monomial M2."
132 (map-into result #'- m1 m2))
133
134(defun monom-mul (m1 m2 &aux (result (copy-seq m1)))
135 "Multiply monomial M1 by monomial M2."
136 (map-into result #'+ m1 m2))
137
138(defun monom-divides-p (m1 m2)
139 "Returns T if monomial M1 divides monomial M2, NIL otherwise."
140 (every #'<= m1 m2))
141
142(defun monom-divides-monom-lcm-p (m1 m2 m3)
143 "Returns T if monomial M1 divides MONOM-LCM(M2,M3), NIL otherwise."
144 (every #'(lambda (x y z) (<= x (max y z)))
145 m1 m2 m3))
146
147(defun monom-lcm-divides-monom-lcm-p (m1 m2 m3 m4)
148 "Returns T if monomial MONOM-LCM(M1,M2) divides MONOM-LCM(M3,M4), NIL otherwise."
149 (every #'(lambda (x y z w) (<= (max x y) (max z w)))
150 m1 m2 m3 m4))
151
152
153(defun monom-lcm-equal-monom-lcm-p (m1 m2 m3 m4)
154 "Returns T if monomial MONOM-LCM(M1,M2) equals MONOM-LCM(M3,M4), NIL otherwise."
155 (every #'(lambda (x y z w) (= (max x y) (max z w)))
156 m1 m2 m3 m4))
157
158
159(defun monom-divisible-by-p (m1 m2)
160 "Returns T if monomial M1 is divisible by monomial M2, NIL otherwise."
161 (every #'>= m1 m2))
162
163(defun monom-rel-prime-p (m1 m2)
164 "Returns T if two monomials M1 and M2 are relatively prime (disjoint)."
165 (every #'(lambda (x y) (zerop (min x y))) m1 m2))
166
167(defun monom-equal-p (m1 m2)
168 "Returns T if two monomials M1 and M2 are equal."
169 (every #'= m1 m2))
170
171(defun monom-lcm (m1 m2 &aux (result (copy-seq m1)))
172 "Returns least common multiple of monomials M1 and M2."
173 (map-into result #'max m1 m2))
174
175(defun monom-gcd (m1 m2 &aux (result (copy-seq m1)))
176 "Returns greatest common divisor of monomials M1 and M2."
177 (map-into result #'min m1 m2))
178
179(defun monom-depends-p (m k)
180 "Return T if the monomial M depends on variable number K."
181 (plusp (monom-elt m k)))
182
183(defmacro monom-map (fun m &rest ml &aux (result `(copy-seq ,m)))
184 `(map-into ,result ,fun ,m ,@ml))
185
186(defmacro monom-append (m1 m2)
187 `(concatenate 'monom ,m1 ,m2))
188
189(defmacro monom-contract (k m)
190 `(setf ,m (subseq ,m ,k)))
191
192(defun make-monom-variable (nvars pos &optional (power 1)
193 &aux (m (make-monom :dimension nvars)))
194 "Construct a monomial in the polynomial ring
195RING[X[0],X[1],X[2],...X[NVARS-1]] over the (unspecified) ring RING
196which represents a single variable. It assumes number of variables
197NVARS and the variable is at position POS. Optionally, the variable
198may appear raised to power POWER. "
199 (setf (monom-elt m pos) power)
200 m)
201
202(defun monom->list (m)
203 "A human-readable representation of a monomial M as a list of exponents."
204 (coerce m 'list))
Note: See TracBrowser for help on using the repository browser.