close Warning: Can't synchronize with repository "(default)" (The repository directory has changed, you should resynchronize the repository with: trac-admin $ENV repository resync '(default)'). Look in the Trac log for more information.

source: branches/f4grobner/ideal.lisp@ 1457

Last change on this file since 1457 was 1436, checked in by Marek Rychlik, 9 years ago

* empty log message *
File size: 9.6 KB
Line 
1;;; -*- Mode: Lisp -*-
2;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
3;;;
4;;; Copyright (C) 1999, 2002, 2009, 2015 Marek Rychlik <rychlik@u.arizona.edu>
5;;;
6;;; This program is free software; you can redistribute it and/or modify
7;;; it under the terms of the GNU General Public License as published by
8;;; the Free Software Foundation; either version 2 of the License, or
9;;; (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
19;;;
20;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
21
22;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
23;;
24;; Operations in ideal theory
25;;
26;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
27
28(defpackage "IDEAL"
29 (:use :cl :ring :monomial :order :term :polynomial :division :grobner-wrap :ring-and-order)
30 (:export "POLY-DEPENDS-P"
31 "RING-INTERSECTION"
32 "ELIMINATION-IDEAL"
33 "COLON-IDEAL"
34 "COLON-IDEAL-1"
35 "IDEAL-INTERSECTION"
36 "POLY-LCM"
37 "GROBNER-EQUAL"
38 "GROBNER-SUBSETP"
39 "GROBNER-MEMBER"
40 "IDEAL-SATURATION-1"
41 "IDEAL-SATURATION"
42 "IDEAL-POLYSATURATION-1"
43 "IDEAL-POLYSATURATION"
44 ))
45
46(in-package :ideal)
47
48;; Does the term depend on variable K?
49(defun term-depends-p (term k)
50 "Return T if the term TERM depends on variable number K."
51 (monom-depends-p (term-monom term) k))
52
53;; Does the polynomial P depend on variable K?
54(defun poly-depends-p (p k)
55 "Return T if the term polynomial P depends on variable number K."
56 (some #'(lambda (term) (term-depends-p term k)) (poly-termlist p)))
57
58(defun ring-intersection (plist k)
59 "This function assumes that polynomial list PLIST is a Grobner basis
60and it calculates the intersection with the ring R[x[k+1],...,x[n]], i.e.
61it discards polynomials which depend on variables x[0], x[1], ..., x[k]."
62 (dotimes (i k plist)
63 (setf plist
64 (remove-if #'(lambda (p)
65 (poly-depends-p p i))
66 plist))))
67
68(defun elimination-ideal (ring-and-order flist k &optional (top-reduction-only $poly_top_reduction_only) (start 0))
69 (ring-intersection (reduced-grobner ring-and-order flist start top-reduction-only) k))
70
71(defun colon-ideal (ring-and-order f g
72 &optional
73 (top-reduction-only $poly_top_reduction_only)
74 &aux
75 (ring (ro-ring ring-and-order)))
76 "Returns the reduced Grobner basis of the colon ideal Id(F):Id(G),
77where F and G are two lists of polynomials. The colon ideal I:J is
78defined as the set of polynomials H such that for all polynomials W in
79J the polynomial W*H belongs to I."
80 (declare (type ring-and-order ring-and-order))
81 (cond
82 ((endp g)
83 ;;Id(G) consists of 0 only so W*0=0 belongs to Id(F)
84 (if (every #'poly-zerop f)
85 (error "First ideal must be non-zero.")
86 (list (make-poly-from-termlist
87 (list (make-term
88 (make-monom :dimension (monom-dimension (poly-lm (find-if-not #'poly-zerop f))))
89 (funcall (ring-unit ring))))))))
90 ((endp (cdr g))
91 (colon-ideal-1 ring-and-order f (car g) top-reduction-only))
92 (t
93 (ideal-intersection ring-and-order
94 (colon-ideal-1 ring-and-order f (car g) top-reduction-only)
95 (colon-ideal ring-and-order f (rest g) top-reduction-only)
96 top-reduction-only))))
97
98(defun colon-ideal-1 (ring-and-order f g
99 &optional
100 (top-reduction-only $poly_top_reduction_only))
101 "Returns the reduced Grobner basis of the colon ideal Id(F):Id({G}), where
102F is a list of polynomials and G is a polynomial."
103 (declare (type ring-and-order ring-and-order))
104 (mapcar #'(lambda (x)
105 (poly-exact-divide ring-and-order x g))
106 (ideal-intersection ring-and-order f (list g) top-reduction-only)))
107
108(defun ideal-intersection (ring-and-order f g
109 &optional
110 (top-reduction-only $poly_top_reduction_only)
111 (ring (ro-ring ring-and-order)))
112 (declare (type ring-and-order ring-and-order))
113 (mapcar #'poly-contract
114 (ring-intersection
115 (reduced-grobner
116 ring-and-order
117 (append (mapcar #'(lambda (p) (poly-extend p (make-monom :dimension 1 :initial-exponent 1))) f)
118 (mapcar #'(lambda (p)
119 (poly-append (poly-extend (poly-uminus ring p)
120 (make-monom :dimension 1 :initial-exponent 1))
121 (poly-extend p)))
122 g))
123 0
124 top-reduction-only)
125 1)))
126
127(defun poly-lcm (ring-and-order f g &aux (ring (ro-ring ring-and-order)))
128 "Return LCM (least common multiple) of two polynomials F and G.
129The polynomials must be ordered according to monomial order PRED
130and their coefficients must be compatible with the RING structure
131defined in the COEFFICIENT-RING package."
132 (cond
133 ((poly-zerop f) f)
134 ((poly-zerop g) g)
135 ((and (endp (cdr (poly-termlist f))) (endp (cdr (poly-termlist g))))
136 (let ((m (monom-lcm (poly-lm f) (poly-lm g))))
137 (make-poly-from-termlist (list (make-term m (funcall (ring-lcm ring) (poly-lc f) (poly-lc g)))))))
138 (t
139 (multiple-value-bind (f f-cont)
140 (poly-primitive-part ring f)
141 (multiple-value-bind (g g-cont)
142 (poly-primitive-part ring g)
143 (scalar-times-poly
144 ring
145 (funcall (ring-lcm ring) f-cont g-cont)
146 (poly-primitive-part ring (car (ideal-intersection ring-and-order (list f) (list g) nil)))))))))
147
148;; Do two Grobner bases yield the same ideal?
149(defun grobner-equal (ring-and-order g1 g2)
150 "Returns T if two lists of polynomials G1 and G2, assumed to be Grobner bases,
151generate the same ideal, and NIL otherwise."
152 (declare (type ring-and-order ring-and-order))
153 (and (grobner-subsetp ring-and-order g1 g2) (grobner-subsetp ring-and-order g2 g1)))
154
155(defun grobner-subsetp (ring-and-order g1 g2)
156 "Returns T if a list of polynomials G1 generates
157an ideal contained in the ideal generated by a polynomial list G2,
158both G1 and G2 assumed to be Grobner bases. Returns NIL otherwise."
159 (declare (type ring-and-order ring-and-order))
160 (every #'(lambda (p) (grobner-member ring-and-order p g2)) g1))
161
162(defun grobner-member (ring-and-order p g)
163 "Returns T if a polynomial P belongs to the ideal generated by the
164polynomial list G, which is assumed to be a Grobner basis. Returns NIL otherwise."
165 (declare (type ring-and-order ring-and-order))
166 (poly-zerop (normal-form ring-and-order p g nil)))
167
168;; Calculate F : p^inf
169(defun ideal-saturation-1 (ring-and-order f p start
170 &optional
171 (top-reduction-only $poly_top_reduction_only))
172 "Returns the reduced Grobner basis of the saturation of the ideal
173generated by a polynomial list F in the ideal generated by a single
174polynomial P. The saturation ideal is defined as the set of
175polynomials H such for some natural number n (* (EXPT P N) H) is in the ideal
176F. Geometrically, over an algebraically closed field, this is the set
177of polynomials in the ideal generated by F which do not identically
178vanish on the variety of P."
179 (declare (type ring-and-order ring-and-order))
180 (mapcar
181 #'poly-contract
182 (ring-intersection
183 (reduced-grobner
184 ring-and-order
185 (saturation-extension-1 ring-and-order f p)
186 start top-reduction-only)
187 1)))
188
189
190;; Calculate F : p1^inf : p2^inf : ... : ps^inf
191(defun ideal-polysaturation-1 (ring-and-order f plist start
192 &optional
193 (top-reduction-only $poly_top_reduction_only))
194 "Returns the reduced Grobner basis of the ideal obtained by a
195sequence of successive saturations in the polynomials
196of the polynomial list PLIST of the ideal generated by the
197polynomial list F."
198 (cond
199 ((endp plist)
200 (reduced-grobner ring-and-order f start top-reduction-only))
201 (t (let ((g (ideal-saturation-1 ring-and-order f (car plist) start top-reduction-only)))
202 (ideal-polysaturation-1 ring-and-order g (rest plist) (length g) top-reduction-only)))))
203
204(defun ideal-saturation (ring-and-order f g start &optional (top-reduction-only $poly_top_reduction_only)
205 &aux
206 (k (length g)))
207 "Returns the reduced Grobner basis of the saturation of the ideal
208generated by a polynomial list F in the ideal generated a polynomial
209list G. The saturation ideal is defined as the set of polynomials H
210such for some natural number n and some P in the ideal generated by G
211the polynomial P**N * H is in the ideal spanned by F. Geometrically,
212over an algebraically closed field, this is the set of polynomials in
213the ideal generated by F which do not identically vanish on the
214variety of G."
215 (mapcar
216 #'(lambda (q) (poly-contract q k))
217 (ring-intersection
218 (reduced-grobner ring-and-order
219 (polysaturation-extension ring-and-order f g)
220 start
221 top-reduction-only)
222 k)))
223
224(defun ideal-polysaturation (ring-and-order f ideal-list start
225 &optional
226 (top-reduction-only $poly_top_reduction_only))
227 "Returns the reduced Grobner basis of the ideal obtained by a
228successive applications of IDEAL-SATURATION to F and lists of
229polynomials in the list IDEAL-LIST."
230 (cond
231 ((endp ideal-list) f)
232 (t (let ((h (ideal-saturation ring-and-order f (car ideal-list) start top-reduction-only)))
233 (ideal-polysaturation ring-and-order h (rest ideal-list) (length h) top-reduction-only)))))
Note: See TracBrowser for help on using the repository browser.