close Warning: Can't synchronize with repository "(default)" (The repository directory has changed, you should resynchronize the repository with: trac-admin $ENV repository resync '(default)'). Look in the Trac log for more information.

source: branches/f4grobner/ideal.lisp@ 1431

Last change on this file since 1431 was 1431, checked in by Marek Rychlik, 9 years ago

* empty log message *
File size: 9.5 KB
Line 
1;;; -*- Mode: Lisp -*-
2;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
3;;;
4;;; Copyright (C) 1999, 2002, 2009, 2015 Marek Rychlik <rychlik@u.arizona.edu>
5;;;
6;;; This program is free software; you can redistribute it and/or modify
7;;; it under the terms of the GNU General Public License as published by
8;;; the Free Software Foundation; either version 2 of the License, or
9;;; (at your option) any later version.
10;;;
11;;; This program is distributed in the hope that it will be useful,
12;;; but WITHOUT ANY WARRANTY; without even the implied warranty of
13;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
14;;; GNU General Public License for more details.
15;;;
16;;; You should have received a copy of the GNU General Public License
17;;; along with this program; if not, write to the Free Software
18;;; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
19;;;
20;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
21
22;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
23;;
24;; Operations in ideal theory
25;;
26;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
27
28(defpackage "IDEAL"
29 (:use :cl :ring :monomial :order :term :polynomial :division :grobner-wrap :ring-and-order)
30 (:export "POLY-DEPENDS-P"
31 "RING-INTERSECTION"
32 "ELIMINATION-IDEAL"
33 "COLON-IDEAL"
34 "COLON-IDEAL-1"
35 "IDEAL-INTERSECTION"
36 "POLY-LCM"
37 "GROBNER-EQUAL"
38 "GROBNER-SUBSETP"
39 "GROBNER-MEMBER"
40 "IDEAL-SATURATION-1"
41 "IDEAL-SATURATION"
42 "IDEAL-POLYSATURATION-1"
43 "IDEAL-POLYSATURATION"
44 ))
45
46(in-package :ideal)
47
48;; Does the term depend on variable K?
49(defun term-depends-p (term k)
50 "Return T if the term TERM depends on variable number K."
51 (monom-depends-p (term-monom term) k))
52
53;; Does the polynomial P depend on variable K?
54(defun poly-depends-p (p k)
55 "Return T if the term polynomial P depends on variable number K."
56 (some #'(lambda (term) (term-depends-p term k)) (poly-termlist p)))
57
58(defun ring-intersection (plist k)
59 "This function assumes that polynomial list PLIST is a Grobner basis
60and it calculates the intersection with the ring R[x[k+1],...,x[n]], i.e.
61it discards polynomials which depend on variables x[0], x[1], ..., x[k]."
62 (dotimes (i k plist)
63 (setf plist
64 (remove-if #'(lambda (p)
65 (poly-depends-p p i))
66 plist))))
67
68(defun elimination-ideal (ring-and-order flist k &optional (top-reduction-only $poly_top_reduction_only) (start 0))
69 (ring-intersection (reduced-grobner ring-and-order flist start top-reduction-only) k))
70
71(defun colon-ideal (ring-and-order f g
72 &optional
73 (top-reduction-only $poly_top_reduction_only)
74 &aux
75 (ring (ro-ring ring-and-order)))
76 "Returns the reduced Grobner basis of the colon ideal Id(F):Id(G),
77where F and G are two lists of polynomials. The colon ideal I:J is
78defined as the set of polynomials H such that for all polynomials W in
79J the polynomial W*H belongs to I."
80 (declare (type ring-and-order ring-and-order))
81 (cond
82 ((endp g)
83 ;;Id(G) consists of 0 only so W*0=0 belongs to Id(F)
84 (if (every #'poly-zerop f)
85 (error "First ideal must be non-zero.")
86 (list (make-poly-from-termlist
87 (list (make-term
88 (make-monom :dimension (monom-dimension (poly-lm (find-if-not #'poly-zerop f))))
89 (funcall (ring-unit ring))))))))
90 ((endp (cdr g))
91 (colon-ideal-1 ring-and-order f (car g) top-reduction-only))
92 (t
93 (ideal-intersection ring-and-order
94 (colon-ideal-1 ring-and-order f (car g) top-reduction-only)
95 (colon-ideal ring-and-order f (rest g) top-reduction-only)
96 top-reduction-only))))
97
98(defun colon-ideal-1 (ring-and-order f g
99 &optional
100 (top-reduction-only $poly_top_reduction_only))
101 "Returns the reduced Grobner basis of the colon ideal Id(F):Id({G}), where
102F is a list of polynomials and G is a polynomial."
103 (declare (type ring-and-order ring-and-order))
104 (mapcar #'(lambda (x)
105 (poly-exact-divide ring-and-order x g))
106 (ideal-intersection ring-and-order f (list g) top-reduction-only)))
107
108(defun ideal-intersection (ring-and-order f g
109 &optional
110 (top-reduction-only $poly_top_reduction_only))
111 (declare (type ring-and-order ring-and-order))
112 (mapcar #'poly-contract
113 (ring-intersection
114 (reduced-grobner
115 ring-and-order
116 (append (mapcar #'(lambda (p) (poly-extend p (make-monom :dimension 1 :initial-exponent 1))) f)
117 (mapcar #'(lambda (p)
118 (poly-append (poly-extend (poly-uminus ring-and-order p)
119 (make-monom :dimension 1 :initial-exponent 1))
120 (poly-extend p)))
121 g))
122 0
123 top-reduction-only)
124 1)))
125
126(defun poly-lcm (ring-and-order f g &aux (ring (ro-ring ring-and-order)))
127 "Return LCM (least common multiple) of two polynomials F and G.
128The polynomials must be ordered according to monomial order PRED
129and their coefficients must be compatible with the RING structure
130defined in the COEFFICIENT-RING package."
131 (cond
132 ((poly-zerop f) f)
133 ((poly-zerop g) g)
134 ((and (endp (cdr (poly-termlist f))) (endp (cdr (poly-termlist g))))
135 (let ((m (monom-lcm (poly-lm f) (poly-lm g))))
136 (make-poly-from-termlist (list (make-term m (funcall (ring-lcm ring) (poly-lc f) (poly-lc g)))))))
137 (t
138 (multiple-value-bind (f f-cont)
139 (poly-primitive-part ring f)
140 (multiple-value-bind (g g-cont)
141 (poly-primitive-part ring g)
142 (scalar-times-poly
143 ring
144 (funcall (ring-lcm ring) f-cont g-cont)
145 (poly-primitive-part ring (car (ideal-intersection ring-and-order (list f) (list g) nil)))))))))
146
147;; Do two Grobner bases yield the same ideal?
148(defun grobner-equal (ring-and-order g1 g2)
149 "Returns T if two lists of polynomials G1 and G2, assumed to be Grobner bases,
150generate the same ideal, and NIL otherwise."
151 (declare (type ring-and-order ring-and-order))
152 (and (grobner-subsetp ring-and-order g1 g2) (grobner-subsetp ring-and-order g2 g1)))
153
154(defun grobner-subsetp (ring-and-order g1 g2)
155 "Returns T if a list of polynomials G1 generates
156an ideal contained in the ideal generated by a polynomial list G2,
157both G1 and G2 assumed to be Grobner bases. Returns NIL otherwise."
158 (declare (type ring-and-order ring-and-order))
159 (every #'(lambda (p) (grobner-member ring-and-order p g2)) g1))
160
161(defun grobner-member (ring-and-order p g)
162 "Returns T if a polynomial P belongs to the ideal generated by the
163polynomial list G, which is assumed to be a Grobner basis. Returns NIL otherwise."
164 (declare (type ring-and-order ring-and-order))
165 (poly-zerop (normal-form ring-and-order p g nil)))
166
167;; Calculate F : p^inf
168(defun ideal-saturation-1 (ring-and-order f p start
169 &optional
170 (top-reduction-only $poly_top_reduction_only))
171 "Returns the reduced Grobner basis of the saturation of the ideal
172generated by a polynomial list F in the ideal generated by a single
173polynomial P. The saturation ideal is defined as the set of
174polynomials H such for some natural number n (* (EXPT P N) H) is in the ideal
175F. Geometrically, over an algebraically closed field, this is the set
176of polynomials in the ideal generated by F which do not identically
177vanish on the variety of P."
178 (declare (type ring-and-order ring-and-order))
179 (mapcar
180 #'poly-contract
181 (ring-intersection
182 (reduced-grobner
183 ring-and-order
184 (saturation-extension-1 ring-and-order f p)
185 start top-reduction-only)
186 1)))
187
188
189;; Calculate F : p1^inf : p2^inf : ... : ps^inf
190(defun ideal-polysaturation-1 (ring-and-order f plist start
191 &optional
192 (top-reduction-only $poly_top_reduction_only))
193 "Returns the reduced Grobner basis of the ideal obtained by a
194sequence of successive saturations in the polynomials
195of the polynomial list PLIST of the ideal generated by the
196polynomial list F."
197 (cond
198 ((endp plist)
199 (reduced-grobner ring-and-order f start top-reduction-only))
200 (t (let ((g (ideal-saturation-1 ring-and-order f (car plist) start top-reduction-only)))
201 (ideal-polysaturation-1 ring-and-order g (rest plist) (length g) top-reduction-only)))))
202
203(defun ideal-saturation (ring-and-order f g start &optional (top-reduction-only $poly_top_reduction_only)
204 &aux
205 (k (length g)))
206 "Returns the reduced Grobner basis of the saturation of the ideal
207generated by a polynomial list F in the ideal generated a polynomial
208list G. The saturation ideal is defined as the set of polynomials H
209such for some natural number n and some P in the ideal generated by G
210the polynomial P**N * H is in the ideal spanned by F. Geometrically,
211over an algebraically closed field, this is the set of polynomials in
212the ideal generated by F which do not identically vanish on the
213variety of G."
214 (mapcar
215 #'(lambda (q) (poly-contract q k))
216 (ring-intersection
217 (reduced-grobner ring-and-order
218 (polysaturation-extension ring-and-order f g)
219 start
220 top-reduction-only)
221 k)))
222
223(defun ideal-polysaturation (ring-and-order f ideal-list start
224 &optional
225 (top-reduction-only $poly_top_reduction_only))
226 "Returns the reduced Grobner basis of the ideal obtained by a
227successive applications of IDEAL-SATURATION to F and lists of
228polynomials in the list IDEAL-LIST."
229 (cond
230 ((endp ideal-list) f)
231 (t (let ((h (ideal-saturation ring-and-order f (car ideal-list) start top-reduction-only)))
232 (ideal-polysaturation ring-and-order h (rest ideal-list) (length h) top-reduction-only)))))
Note: See TracBrowser for help on using the repository browser.